# $Id: PKGBUILD 108823 2011-02-03 20:52:35Z thomas $
# Maintainer: judd <jvinet@zeroflux.org>

pkgname=util-linux
pkgver=2.19
pkgrel=1
pkgdesc="Miscellaneous system utilities for Linux"
url="http://userweb.kernel.org/~kzak/util-linux/"
arch=('i686' 'x86_64')
groups=('base')
depends=('bash' 'ncurses>=5.7' 'zlib' 'filesystem')
replaces=('util-linux-ng')
conflicts=('util-linux-ng' 'e2fsprogs<1.41.8-2')
license=('GPL2')
options=('!libtool')
source=("ftp://ftp.kernel.org/pub/linux/utils/util-linux/v$pkgver/$pkgname-$pkgver.tar.bz2")
optdepends=('perl: for chkdupexe support')
md5sums=('590ca71aad0b254e2631d84401f28255')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  # relocate hwclock adjustment file
  sed -e 's%etc/adjtime%var/lib/hwclock/adjtime%' -i hwclock/hwclock.c

  ./autogen.sh
  ./configure --enable-arch --enable-write --enable-raw --disable-wall --enable-partx

  make HAVE_SLN=yes ADD_RAW=yes
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make HAVE_SLN=yes ADD_RAW=yes DESTDIR="$pkgdir" install

  install -dm755 "${pkgdir}/var/lib/hwclock"
}