Re: [pacman-dev] makepkg-git package

17 Jan 2009

      Hi,

just tested it on a quickly-ported KDEmod PKGBUILD, it works fine.
I have found nothing uncommon so far and the packages are
valid and working, awesome! :)

Here is the PKGBUILD:

---------------------------------------------------------------------------------------

# include global config
# source ../_buildsystem/kdemod.conf

# original name
_origname=kdetoys

pkgname=('kdemod-kdetoys-common' 'kdemod-kdetoys-doc' 'kdemod-kdetoys-amor' 
'kdemod-kdetoys-kteatime' 'kdemod-kdetoys-ktux' 'kdemod-kdetoys-kweather')
arch=('i686' 'x86_64')
pkgver=4.1.96
pkgrel=1

pkgdesc="KDE toys"
url="http://www.kde.org"
license=('GPL')

options=('docs')

makedepends=('pkgconfig' 'cmake' 'automoc4' 'kdemod-kdebase-workspace')

source=(${_origname}-${pkgver}.tar.bz2)
md5sums=('f99460c59656136d897845eb2fe46932')

build() {
	cd $srcdir/${_origname}-${pkgver}

	# stable branch update
	if [ "$_branchupdate" = "yes" ] ; then
		msg "applying branch update ..."
		patch -Np0 -i $startdir/branch-update.patch || return 1
	else
		warning "branch update disabled ..."
		warning "if you want to make use of it, run branch_updater.sh"
		warning "and enable the branch updates in _/buildsystem/kdemod.conf"
	fi

	msg "starting build ..."
	cmake . -DCMAKE_BUILD_TYPE=RelWithDebInfo \
		-DCMAKE_INSTALL_PREFIX=/usr

	make || return 1
}

package_kdemod-kdetoys-common() {
		pkgdesc="KDE toys - Common files"
		depends=('kdemod-kdebase-workspace')
		provides=("kdetoys=${pkgver}")
		conflicts=('kdetoys')
		groups=('kdemod-complete' 'kdemod-kdetoys' 'kdemod-uninstall')
		install=kdetoys.install
}

package_kdemod-kdetoys-doc() {
		pkgdesc="KDE Toys - Documentation"
		depends=('kdemod-kdetoys-common')
		groups=('kdemod-complete' 'kdemod-kdetoys' 'kdemod-doc' 'kdemod-uninstall')

		splitfolders="doc"
			for i in $splitfolders ; do
				cd $srcdir/${_origname}-${pkgver}/$i
				make DESTDIR=$pkgdir install || return 1
			done
}

package_kdemod-kdetoys-amor() {
		pkgdesc="Amusing Misuse Of Resources puts comic figures above your windows"
		depends=('kdemod-kdetoys-common')
		groups=('kdemod-complete' 'kdemod-kdetoys' 'kdemod-uninstall')
		install=kdetoys.install

		splitfolders="amor"
			for i in $splitfolders ; do
				cd $srcdir/${_origname}-${pkgver}/$i
				make DESTDIR=$pkgdir install || return 1
			done
}

package_kdemod-kdetoys-kteatime() {
		pkgdesc="System tray applet that makes sure your tea doesn't get too strong"
		depends=('kdemod-kdetoys-common')
		groups=('kdemod-complete' 'kdemod-kdetoys' 'kdemod-uninstall')
		install=kdetoys.install

		splitfolders="kteatime"
			for i in $splitfolders ; do
				cd $srcdir/${_origname}-${pkgver}/$i
				make DESTDIR=$pkgdir install || return 1
			done
}

package_kdemod-kdetoys-ktux() {
		pkgdesc="Tux-in-a-Spaceship screen saver"
		depends=('kdemod-kdetoys-common')
		groups=('kdemod-complete' 'kdemod-kdetoys' 'kdemod-uninstall')
		install=kdetoys.install

		splitfolders="ktux"
			for i in $splitfolders ; do
				cd $srcdir/${_origname}-${pkgver}/$i
				make DESTDIR=$pkgdir install || return 1
			done
}

package_kdemod-kdetoys-kweather() {
		pkgdesc="Panel applet that will display the current weather outside"
		depends=('kdemod-kdetoys-common')
		groups=('kdemod-complete' 'kdemod-kdetoys' 'kdemod-uninstall')
		install=kdetoys.install

		splitfolders="kweather"
			for i in $splitfolders ; do
				cd $srcdir/${_origname}-${pkgver}/$i
				make DESTDIR=$pkgdir install || return 1
			done
}

Re: [pacman-dev] makepkg-git package

Jan Mette