[arch-commits] Commit in empathy/trunk (PKGBUILD empathy.install)

Jan de Groot jgc at archlinux.org
Sat Oct 11 21:03:23 UTC 2008


    Date: Saturday, October 11, 2008 @ 17:03:23
  Author: jgc
Revision: 14974

upgpkg: empathy 2.24.0-1

Added:
  empathy/trunk/PKGBUILD
  empathy/trunk/empathy.install

-----------------+
 PKGBUILD        |   39 +++++++++++++++++++++++++++++++++++++++
 empathy.install |   22 ++++++++++++++++++++++
 2 files changed, 61 insertions(+)

Added: PKGBUILD
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2008-10-11 21:03:23 UTC (rev 14974)
@@ -0,0 +1,39 @@
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Contributor: Bjorn Lindeijer <bjorn lindeijer nl>
+# Contributor: arjan <arjan at archlinux.org>
+# Contributor: Brice Carpentier <brice at dlfp.org>
+# Contributor: Andreas Zwinkau <beza1e1 at web.de>
+# Contributor: M Rawash <mrawash at gmail.com>
+
+pkgname=empathy
+pkgver=2.24.0
+pkgrel=1
+pkgdesc="A GNOME instant messaging client using the Telepathy framework."
+arch=('i686' 'x86_64')
+url="http://live.gnome.org/Empathy"
+license=('GPL2')
+depends=('enchant>=1.4.2' 'telepathy-mission-control>=4.61' 'iso-codes' 'evolution-data-server>=2.24.0')
+makedepends=('pkgconfig' 'intltool' 'gnome-doc-utils>=0.14.0' 'gnome-panel>=2.24.0')
+optdepends=('telepathy-gabble: XMPP/Jabber'
+            'telepathy-butterfly: MSN'
+	    'telepathy-idle: IRC'
+	    'telepathy-salut: Link-local XMPP'
+	    'telepathy-sofiasip: SIP'
+	    'telepathy-haze: libpurple')
+options=(!libtool !emptydirs)
+install=empathy.install
+source=(http://ftp.gnome.org/pub/GNOME/sources/${pkgname}/2.24/${pkgname}-${pkgver}.tar.bz2)
+md5sums=('89e6dc430ad198c8044f261645d8bc6c')
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  ./configure --prefix=/usr --sysconfdir=/etc --enable-voip=yes \
+              --libexecdir=/usr/lib/empathy || return 1
+  make || return 1
+  make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 \
+       DESTDIR="${pkgdir}" install || return 1
+
+  install -m755 -d "${pkgdir}/usr/share/gconf/schemas"
+  gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas" ${pkgdir}/etc/gconf/schemas/*.schemas
+  rm -f ${pkgdir}/etc/gconf/schemas/*.schemas
+}

Added: empathy.install
===================================================================
--- empathy.install	                        (rev 0)
+++ empathy.install	2008-10-11 21:03:23 UTC (rev 14974)
@@ -0,0 +1,22 @@
+pkgname=empathy
+
+post_install() {
+  usr/sbin/gconfpkg --install ${pkgname}
+  gtk-icon-update -q -t -f usr/share/icons/hicolor
+}
+
+pre_upgrade() {
+  pre_remove $1
+}
+
+post_upgrade() {
+  post_install $1
+}
+
+pre_remove() {
+  usr/sbin/gconfpkg --uninstall ${pkgname}
+}
+
+post_remove() {
+  gtk-icon-update -q -t -f usr/share/icons/hicolor
+}




More information about the arch-commits mailing list