[arch-commits] Commit in filesystem/trunk (PKGBUILD)

[Pierre Schmitz]

    Date: Thursday, November 18, 2010 @ 13:25:57
  Author: pierre
Revision: 99849

Rewrite PKGBUILD and make it more readable

Modified:
  filesystem/trunk/PKGBUILD

----------+
 PKGBUILD |  118 +++++++++++++++++++++++++++++++------------------------------
 1 file changed, 60 insertions(+), 58 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2010-11-18 16:39:53 UTC (rev 99848)
+++ PKGBUILD	2010-11-18 18:25:57 UTC (rev 99849)
@@ -1,23 +1,22 @@
 # $Id$
-# Maintainer: Aaron Griffin <aaron at archlinux.org>
-# Contributor: judd <jvinet at zeroflux.org>
+# Maintainer: Pierre Schmitz <pierre at archlinux.de>
 
 pkgname=filesystem
 pkgver=2010.11
 pkgrel=1
-pkgdesc="Base filesystem"
+pkgdesc='Base filesystem'
 arch=('any')
 license=('GPL')
-url="http://www.archlinux.org"
+url='http://www.archlinux.org'
 groups=('base')
-install=filesystem.install
+install='filesystem.install'
 depends=('iana-etc' 'bash' 'coreutils')
-backup=(etc/fstab etc/crypttab etc/group etc/hosts etc/ld.so.conf etc/passwd
-        etc/shadow etc/gshadow etc/resolv.conf etc/motd etc/nsswitch.conf
-        etc/shells etc/host.conf etc/securetty etc/profile etc/issue)
-source=(group issue nsswitch.conf securetty host.conf ld.so.conf
-        passwd shadow fstab crypttab hosts motd resolv.conf shells
-        gshadow profile modprobe.d.usb-load-ehci-first)
+backup=('etc/fstab' 'etc/crypttab' 'etc/group' 'etc/hosts' 'etc/ld.so.conf' 'etc/passwd'
+        'etc/shadow' 'etc/gshadow' 'etc/resolv.conf' 'etc/motd' 'etc/nsswitch.conf'
+        'etc/shells' 'etc/host.conf' 'etc/securetty' 'etc/profile' 'etc/issue')
+source=('group' 'issue' 'nsswitch.conf' 'securetty' 'host.conf' 'ld.so.conf'
+        'passwd' 'shadow' 'fstab' 'crypttab' 'hosts' 'motd' 'resolv.conf' 'shells'
+        'gshadow' 'profile' 'modprobe.d.usb-load-ehci-first')
 md5sums=('75c7e1770305e1f3b75c52785c137611'
          '1bdc5dba66947d74866a5df8ce9ef3b1'
          '13753e4e0964f3652b0cc60a28528bdf'
@@ -32,61 +31,64 @@
          'd41d8cd98f00b204e9800998ecf8427e'
          '6f48288b6fcaf0065fcb7b0e525413e0'
          '40dac0de4c6b99c8ca97effbd7527c84'
-         '5340b9287b71ffe9d4d99510bffe933f'
+         '59768b5f4080b96b67bcde5f66984ad5'
          'ccc4e6292ae594f16b44c66c7769765c'
          '8098ffd9fbf890468d3198277596b85a')
 
-build()
-{
-  cd ${pkgdir}
-  mkdir -p bin boot dev etc home lib media mnt proc root sbin tmp usr var opt srv sys
-  chmod 555 proc
-  mkdir -p usr/{bin,include,lib,sbin,share/misc,src}
+package() {
+	cd ${srcdir}
 
-  mkdir -p usr/share/man/man{1,2,3,4,5,6,7,8}
+	#
+	# setup root filesystem
+	#
+	for d in bin boot dev etc home lib/modules media mnt sbin usr var opt srv/http sys; do
+		install -d -m755 ${pkgdir}/${d}
+	done
+	install -d -m555 ${pkgdir}/proc
+	install -d -m0750 ${pkgdir}/root
+	install -d -m1777 ${pkgdir}/tmp
+	# vsftpd won't run with write perms on /srv/ftp
+	install -d -m555 -g ftp ${pkgdir}/srv/ftp
 
-  # fhs compliance
-  mkdir -p usr/local/{bin,games,include,lib,man,sbin,share,src}
-  ln -s ../man ${pkgdir}/usr/local/share/man
-  mkdir -p var/{cache/man,local,lock,opt,run,spool/mail,tmp,games}
-  chmod 1777 var/lock
-  mkdir -p var/log/old
-  mkdir -p etc/{ld.so.conf.d,skel,profile.d}
-  mkdir -p lib/modules
-  mkdir -p var/lib/misc
-  (cd ${pkgdir}/var; ln -s spool/mail mail)
+	# setup /etc
+	install -d ${pkgdir}/etc/{ld.so.conf.d,skel,profile.d}
+	for f in fstab group host.conf hosts issue ld.so.conf motd nsswitch.conf passwd resolv.conf securetty shells profile; do
+		install -m644 ${srcdir}/${f} ${pkgdir}/etc/
+	done
+	for f in gshadow shadow crypttab; do
+		install -m600 ${srcdir}/${f} ${pkgdir}/etc/
+	done
+	touch ${pkgdir}/etc/arch-release
+	install -D -m644 ${srcdir}/modprobe.d.usb-load-ehci-first ${pkgdir}/etc/modprobe.d/usb-load-ehci-first.conf
 
-  # vsftpd won't run with write perms on /srv/ftp
-  mkdir -p srv/ftp
-  chown root.ftp srv/ftp
-  chmod 555 srv/ftp
+	# setup /var
+	for d in cache/man local opt run log/old lib/misc empty; do
+		install -d -m755 ${pkgdir}/var/${d}
+	done
+	install -d -m1777 ${pkgdir}/var/{lock,tmp,spool/mail}
+	# allow setgid games to write scores
+	install -d -m775 -g games ${pkgdir}/var/games
+	ln -s spool/mail ${pkgdir}/var/mail
+	# prevent pacman from removing directory (FS#16886)
+	touch ${pkgdir}/var/empty/.keep
 
-  install -d -o root -g root -m 755 srv/http
 
-  chmod 1777 var/spool/mail tmp var/tmp
-  chmod 0750 root
+	#
+	# setup /usr hierarchy
+	#
+	for d in bin include lib sbin share/misc src; do
+		install -d -m755 ${pkgdir}/usr/${d}
+	done
+	for d in $(seq 8); do
+		install -d -m755 ${pkgdir}/usr/share/man/man${d}
+	done
 
-  #Allow setgid games to write scores:
-  chmod 775 ${pkgdir}/var/games
-  chown root:50 ${pkgdir}/var/games
 
-  cd ${srcdir}
-  cp fstab crypttab group host.conf hosts issue ld.so.conf motd nsswitch.conf \
-    passwd resolv.conf securetty shadow shells profile \
-    ${pkgdir}/etc/
-  install -m 600 ${srcdir}/gshadow ${pkgdir}/etc/gshadow
-  chmod 600 ${pkgdir}/etc/shadow
-  chmod 600 ${pkgdir}/etc/crypttab
-
-  # re-add /etc/arch-release, some software uses it
-  # to check whether arch is running
-  touch ${pkgdir}/etc/arch-release
-
-  # Add /etc/modprobe.d/
-  install -D -m644 ${srcdir}/modprobe.d.usb-load-ehci-first \
-    ${pkgdir}/etc/modprobe.d/usb-load-ehci-first.conf
-
-  # Prevent pacman from removing directory (FS#16886)
-  mkdir ${pkgdir}/var/empty
-  touch ${pkgdir}/var/empty/.keep
+	#
+	# setup /usr/local hierarchy
+	#
+	for d in bin etc games include lib man sbin share src; do
+		install -d -m755 ${pkgdir}/usr/local/${d}
+	done
+	ln -s ../man ${pkgdir}/usr/local/share/man
 }