[arch-commits] Commit in (5 files)
Andrea Scarpino
andrea at archlinux.org
Fri Jan 21 00:46:26 UTC 2011
Date: Thursday, January 20, 2011 @ 19:46:26
Author: andrea
Revision: 107070
move python-qt in a new dir
Added:
python-qt/
python-qt/repos/
python-qt/trunk/
python-qt/trunk/PKGBUILD
python-qt/trunk/fix-stackedwidget-bug.patch
-----------------------------+
PKGBUILD | 46 ++++++++++++++++++++++++++++++++++++++++++
fix-stackedwidget-bug.patch | 11 ++++++++++
2 files changed, 57 insertions(+)
Added: python-qt/trunk/PKGBUILD
===================================================================
--- python-qt/trunk/PKGBUILD (rev 0)
+++ python-qt/trunk/PKGBUILD 2011-01-21 00:46:26 UTC (rev 107070)
@@ -0,0 +1,46 @@
+# $Id$
+# Maintainer: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=python-qt
+pkgver=4.8.2
+pkgrel=4
+arch=('i686' 'x86_64')
+url="http://riverbankcomputing.co.uk/software/pyqt/intro"
+license=('GPL')
+pkgdesc="A set of Python 3 bindings for the Qt toolkit"
+depends=('python2-qt' 'python-sip')
+optdepends=('phonon: enable audio and video in PyQt applications'
+ 'qscintilla: QScintilla API'
+ 'qt-assistant-compat: add PyQt online help in Qt Assistant')
+makedepends=('phonon' 'qt-assistant-compat')
+source=("http://riverbankcomputing.co.uk/static/Downloads/PyQt4/PyQt-x11-gpl-${pkgver}.tar.gz"
+ 'fix-stackedwidget-bug.patch')
+md5sums=('142a32f126f205a2bd77f6a9910f5333'
+ '42cfd44a8ec063cce3e328ddb9892565')
+
+build() {
+ cd "${srcdir}/PyQt-x11-gpl-${pkgver}"
+
+ # Already fixed upstream
+ patch -Np1 -i "${srcdir}/fix-stackedwidget-bug.patch"
+
+ python configure.py \
+ --confirm-license \
+ --qsci-api
+
+ # Thanks Gerardo for the rpath fix
+ find -name 'Makefile' | xargs sed -i 's|-Wl,-rpath,/usr/lib||g;s|-Wl,-rpath,.* ||g'
+
+ make
+}
+
+package(){
+ cd "${srcdir}/PyQt-x11-gpl-${pkgver}"
+ # INSTALL_ROOT is needed for the QtDesigner module, the other Makefiles use DESTDIR
+ make DESTDIR="${pkgdir}" INSTALL_ROOT="${pkgdir}" install
+
+ # Provided by python2-qt package
+ rm ${pkgdir}/usr/bin/{pylupdate4,pyrcc4,pyuic4}
+ rm ${pkgdir}/usr/lib/qt/plugins/designer/libpythonplugin.so
+ rm ${pkgdir}/usr/share/qt/qsci/api/python/PyQt4.api
+}
Added: python-qt/trunk/fix-stackedwidget-bug.patch
===================================================================
--- python-qt/trunk/fix-stackedwidget-bug.patch (rev 0)
+++ python-qt/trunk/fix-stackedwidget-bug.patch 2011-01-21 00:46:26 UTC (rev 107070)
@@ -0,0 +1,11 @@
+--- PyQt-x11-gpl-4.8.2/pyuic/uic/uiparser.py~ 2010-12-27 14:01:31.500057960 -0800
++++ PyQt-x11-gpl-4.8.2/pyuic/uic/uiparser.py 2010-12-27 14:01:44.460058033 -0800
+@@ -158,7 +158,7 @@
+ # Ignore the parent if it is a container.
+ parent = self.stack.topwidget
+ if isinstance(parent, (QtGui.QDockWidget, QtGui.QMdiArea,
+- QtGui.QScrollArea, QtGui.StackedWidget,
++ QtGui.QScrollArea, QtGui.QStackedWidget,
+ QtGui.QToolBox, QtGui.QTabWidget,
+ QtGui.QWizard)):
+ parent = None
More information about the arch-commits
mailing list