[arch-commits] Commit in mutt/repos (4 files)

Stéphane Gaudreault stephane at archlinux.org
Thu Nov 24 12:03:00 EST 2011


    Date: Thursday, November 24, 2011 @ 12:02:59
  Author: stephane
Revision: 143467

db-move: moved mutt from [staging] to [testing] (i686)

Added:
  mutt/repos/testing-i686/
  mutt/repos/testing-i686/PKGBUILD
    (from rev 143456, mutt/repos/staging-i686/PKGBUILD)
  mutt/repos/testing-i686/install
    (from rev 143456, mutt/repos/staging-i686/install)
Deleted:
  mutt/repos/staging-i686/

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 install  |    8 ++++++++
 2 files changed, 56 insertions(+)

Copied: mutt/repos/testing-i686/PKGBUILD (from rev 143456, mutt/repos/staging-i686/PKGBUILD)
===================================================================
--- testing-i686/PKGBUILD	                        (rev 0)
+++ testing-i686/PKGBUILD	2011-11-24 17:02:59 UTC (rev 143467)
@@ -0,0 +1,48 @@
+# $Id$
+# Contributor: tobias [tobias [at] archlinux.org]
+# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+
+pkgname=mutt
+pkgver=1.5.21
+pkgrel=6
+pkgdesc='Small but very powerful text-based mail client'
+url='http://www.mutt.org/'
+license=('GPL')
+backup=('etc/Muttrc')
+arch=('i686' 'x86_64')
+optdepends=('smtp-forwarder: to send mail')
+depends=('gpgme' 'ncurses' 'openssl' 'libsasl' 'gdbm' 'libidn' 'mime-types' 'krb5')
+source=("ftp://ftp.mutt.org/mutt/devel/${pkgname}-${pkgver}.tar.gz")
+sha1sums=('a8475f2618ce5d5d33bff85c0affdf21ab1d76b9')
+
+install=install
+
+build() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+	./configure \
+		--prefix=/usr \
+		--sysconfdir=/etc \
+		--enable-gpgme \
+		--enable-pop \
+		--enable-imap \
+		--enable-smtp \
+		--enable-hcache \
+		--with-curses=/usr \
+		--with-regex \
+		--with-gss=/usr \
+		--with-ssl=/usr \
+		--with-sasl \
+		--with-idn \
+
+	make
+}
+
+package() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+	make DESTDIR="${pkgdir}" install
+
+	rm "${pkgdir}"/usr/bin/{flea,muttbug}
+	rm "${pkgdir}"/usr/share/man/man1/{flea,muttbug}.1
+	rm "${pkgdir}"/etc/mime.types{,.dist}
+	install -Dm644 contrib/gpg.rc "${pkgdir}"/etc/Muttrc.gpg.dist
+}

Copied: mutt/repos/testing-i686/install (from rev 143456, mutt/repos/staging-i686/install)
===================================================================
--- testing-i686/install	                        (rev 0)
+++ testing-i686/install	2011-11-24 17:02:59 UTC (rev 143467)
@@ -0,0 +1,8 @@
+post_install() {
+	cat <<EOF
+
+==> For GPG support, add the following to your muttrc:
+==> source /etc/Muttrc.gpg.dist
+
+EOF
+}



More information about the arch-commits mailing list