[arch-commits] Commit in gthumb/repos (4 files)

Jan Steffens heftig at archlinux.org
Sun Apr 1 07:34:31 EDT 2012


    Date: Sunday, April 1, 2012 @ 07:34:30
  Author: heftig
Revision: 155165

db-move: moved gthumb from [gnome-unstable] to [testing] (i686)

Added:
  gthumb/repos/testing-i686/
  gthumb/repos/testing-i686/PKGBUILD
    (from rev 155005, gthumb/repos/gnome-unstable-i686/PKGBUILD)
  gthumb/repos/testing-i686/gthumb.install
    (from rev 155005, gthumb/repos/gnome-unstable-i686/gthumb.install)
Deleted:
  gthumb/repos/gnome-unstable-i686/

----------------+
 PKGBUILD       |   43 +++++++++++++++++++++++++++++++++++++++++++
 gthumb.install |   19 +++++++++++++++++++
 2 files changed, 62 insertions(+)

Copied: gthumb/repos/testing-i686/PKGBUILD (from rev 155005, gthumb/repos/gnome-unstable-i686/PKGBUILD)
===================================================================
--- testing-i686/PKGBUILD	                        (rev 0)
+++ testing-i686/PKGBUILD	2012-04-01 11:34:30 UTC (rev 155165)
@@ -0,0 +1,43 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Tobias Kieslich <tobias at justdreams.de>
+
+pkgname=gthumb
+pkgver=2.90.2
+pkgrel=1
+pkgdesc="Image browser and viewer for the GNOME Desktop"
+arch=(i686 x86_64)
+license=('GPL')
+url="http://live.gnome.org/gthumb"
+depends=('desktop-file-utils' 'hicolor-icon-theme' 'dconf' 'librsvg' 'clutter-gtk'
+         'gstreamer0.10-base')
+makedepends=('intltool' 'gnome-doc-utils' 'libchamplain' 'libopenraw' 'exiv2' 'libsoup-gnome'
+             'brasero' 'librsvg' 'libopenraw' 'liboauth')
+optdepends=('libopenraw: read RAW files'
+            'exiv2: metadata support'
+            'libchamplain: map viewer'
+            'brasero: burn discs'
+            'libsoup-gnome: web albums'
+            'liboauth: web albums')
+options=('!libtool' '!emptydirs')
+install=gthumb.install
+source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz)
+sha256sums=('29a961ede929c172723cb5550977e4bf7cda4921228ed1ddafba09cc6bae4424')
+
+build() {
+  cd $pkgname-$pkgver
+  
+  ./configure --prefix=/usr --sysconfdir=/etc \
+      --localstatedir=/var --disable-static \
+      --enable-libchamplain --enable-libopenraw
+  
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/    if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/      func_append compile_command " -Wl,-O1,--as-needed"\n      func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
+
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+}

Copied: gthumb/repos/testing-i686/gthumb.install (from rev 155005, gthumb/repos/gnome-unstable-i686/gthumb.install)
===================================================================
--- testing-i686/gthumb.install	                        (rev 0)
+++ testing-i686/gthumb.install	2012-04-01 11:34:30 UTC (rev 155165)
@@ -0,0 +1,19 @@
+post_install() {
+  glib-compile-schemas usr/share/glib-2.0/schemas
+  update-desktop-database -q
+  gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
+}
+
+pre_upgrade() {
+  if (( $(vercmp $2 2.90.1) < 0 )); then
+    gconfpkg --uninstall gthumb
+  fi
+}
+
+post_upgrade() {
+  post_install
+}
+
+post_remove() {
+  post_install
+}



More information about the arch-commits mailing list