[arch-commits] Commit in ardour/trunk (PKGBUILD ardour.changelog)

[Ray Rashif]

    Date: Sunday, August 12, 2012 @ 08:55:33
  Author: schiv
Revision: 165178

upgpkg: ardour 2.8.14-1

upstream release

Modified:
  ardour/trunk/PKGBUILD
  ardour/trunk/ardour.changelog

------------------+
 PKGBUILD         |   59 +++++++++++++++++++++++++++++------------------------
 ardour.changelog |    6 +++++
 2 files changed, 39 insertions(+), 26 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2012-08-12 08:15:08 UTC (rev 165177)
+++ PKGBUILD	2012-08-12 12:55:33 UTC (rev 165178)
@@ -1,56 +1,63 @@
 # $Id$
-# Maintainer: tobias <tobias at archlinux.org>
 # Maintainer: Ray Rashif <schiv at archlinux.org>
+# Contributor: tobias <tobias at archlinux.org>
 # Contributor: Giovanni Scafora <giovanni at archlinux.org>
 
 # ardour, liblrdf and raptor are heavily dependent on each other. Updating of
 # one package mostly will require an update of all the other packages. I vote
-# for fixed dependencies speaking in terms of versions
+# for fixed dependencies speaking in terms of versions -- tobias
 
+# SYSLIBS enabled, support still valid; see ardour 2.8.13 rel notes
+
 pkgname=ardour
-pkgver=2.8.12
-pkgrel=3
+pkgver=2.8.14
+pkgrel=1
 pkgdesc="A multichannel hard disk recorder and digital audio workstation"
 arch=('i686' 'x86_64')
 url="http://ardour.org/"
 license=('GPL')
-depends=('liblrdf>=0.4.0-8' 'liblo' 'libusb-compat'
-         'libgnomecanvas' 'aubio' 'slv2>=0.6.6-6')
+depends=('liblrdf' 'libusb-compat' 'liblo' 'soundtouch'
+         'aubio' 'lilv' 'suil' 'libgnomecanvasmm')
          # -libgnomecanvas(+libgnomecanvasmm)
-         # +soundtouch (these +/- changes are for SYSLIBS)
-         # liblrdf versioned for https://bugs.archlinux.org/task/25005
-         # slv2 versioned for https://bugs.archlinux.org/task/25060
+         # +soundtouch (these +/- changes are for SYSLIBS=1)
+         # cwiid removed for https://bugs.archlinux.org/task/28344
 makedepends=('scons' 'boost')
-changelog=${pkgname}.changelog
-source=(ftp://ftp.archlinux.org/other/ardour/${pkgname}-${pkgver}.tar.bz2
-        ${pkgname}.desktop)
-md5sums=('7c031892f53aeacf08a750fc320c79c5'
+changelog=$pkgname.changelog
+source=("ftp://ftp.archlinux.org/other/ardour/$pkgname-$pkgver.tar.bz2"
+        "$pkgname.desktop")
+md5sums=('c79219ba10735d0b061d53a84ae611a4'
          '8aeaf433ebf781733db48e5a16b0c4da')
 
 build() {
-  cd "${srcdir}/${pkgname}-${pkgver}"
+  cd "$srcdir/$pkgname-$pkgver"
 
   sed -i '/-O3/d' SConstruct
 
-  scons ${MAKEFLAGS} ARCH="${CFLAGS} -O3" \
-                     PREFIX="/usr" \
-                     DIST_LIBDIR="lib" \
-                     FREEDESKTOP=0 \
-                     FREESOUND=1 \
-                     SYSLIBS=0 \
-                     DESTDIR="${pkgdir}"
+  # work around boost linking error (see ardour3 svn r13081)
+  # thanks to Harry Harren for the heads-up
+  CFLAGS+=" -DBOOST_SYSTEM_NO_DEPRECATED"
+  CXXFLAGS+=" -DBOOST_SYSTEM_NO_DEPRECATED"
+  export CFLAGS CXXFLAGS
+
+  scons $MAKEFLAGS ARCH="$CFLAGS -O3" \
+                   PREFIX="/usr" \
+                   DIST_LIBDIR="lib" \
+                   FREEDESKTOP=0 \
+                   FREESOUND=1 \
+                   SYSLIBS=1 \
+                   DESTDIR="$pkgdir"
 }
 
 package() {
-  cd "${srcdir}/${pkgname}-${pkgver}"
+  cd "$srcdir/$pkgname-$pkgver"
 
-  scons DESTDIR="${pkgdir}" install
+  scons DESTDIR="$pkgdir" install
 
   # install some freedesktop.org compatibility
-  install -Dm644 "${srcdir}/${pkgname}.desktop" \
-    "${pkgdir}/usr/share/applications/${pkgname}.desktop"
+  install -Dm644 "$srcdir/$pkgname.desktop" \
+    "$pkgdir/usr/share/applications/$pkgname.desktop"
 
-  # TODO: tell upstream to do this
+  # upstream will not do this
   # install templates
   cp -r templates "$pkgdir/usr/share/ardour2/"
 }

Modified: ardour.changelog
===================================================================
--- ardour.changelog	2012-08-12 08:15:08 UTC (rev 165177)
+++ ardour.changelog	2012-08-12 12:55:33 UTC (rev 165178)
@@ -1,3 +1,9 @@
+11 Aug 2012 (GMT+8) Ray Rashif <schiv at archlinux.org>
+	* 2.8.14:
+	Upstream release
+	Dep on new (s)lv2 stack (lilv, suil et al replaces slv2)
+	SYSLIBS turned on by upstream decree; see 2.8.13 release notes
+
 15 Jul 2011 (GMT+8) Ray Rashif <schiv at archlinux.org>
 
 	* 2.8.11-5: