[arch-commits] Commit in python-mako/repos (staging-any staging-any/PKGBUILD)

[Stéphane Gaudreault]

    Date: Tuesday, October 2, 2012 @ 20:41:56
  Author: stephane
Revision: 167686

archrelease: copy trunk to staging-any

Added:
  python-mako/repos/staging-any/
  python-mako/repos/staging-any/PKGBUILD
    (from rev 167685, python-mako/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: python-mako/repos/staging-any/PKGBUILD (from rev 167685, python-mako/trunk/PKGBUILD)
===================================================================
--- staging-any/PKGBUILD	                        (rev 0)
+++ staging-any/PKGBUILD	2012-10-03 00:41:56 UTC (rev 167686)
@@ -0,0 +1,41 @@
+# $Id$
+# Maintainer : Ionut Biru <ibiru at archlinux.org>
+# Contributor: Roberto Alsina <ralsina at kde.org>
+
+pkgname=('python-mako' 'python2-mako')
+pkgver=0.7.2
+pkgrel=2
+pkgdesc="Hyperfast and lightweight templating for the Python2 platform."
+arch=('any')
+url="http://www.makotemplates.org/"
+license=('MIT')
+makedepends=('python-distribute' 'python2-distribute')
+source=("http://www.makotemplates.org/downloads/Mako-$pkgver.tar.gz")
+md5sums=('e3c0a677aa4216da9e89ef8fa76cbafb')
+
+build() {
+    cp -r Mako-$pkgver python2-Mako-$pkgver
+
+    cd "$srcdir/Mako-$pkgver"
+    python3 setup.py build
+
+    cd "$srcdir/python2-Mako-$pkgver"
+    python2 setup.py build
+}
+
+package_python-mako() {
+    depends=('python-markupsafe' 'python-beaker')
+
+    cd "$srcdir/Mako-$pkgver"
+    python3 setup.py install --root="$pkgdir" --optimize=1
+    mv "$pkgdir"/usr/bin/mako-render "$pkgdir"/usr/bin/python3-mako-render
+    install -D LICENSE "$pkgdir/usr/share/licenses/python-mako/COPYING"
+}
+
+package_python2-mako() {
+    depends=('python2-markupsafe' 'python2-beaker')
+
+    cd "$srcdir/python2-Mako-$pkgver"
+    python2 setup.py install --root="$pkgdir" --optimize=1
+    install -D LICENSE "$pkgdir/usr/share/licenses/python2-mako/COPYING"
+}