[arch-commits] Commit in python-feedparser/repos (staging-any staging-any/PKGBUILD)
Eric Bélanger
eric at archlinux.org
Thu Oct 4 20:53:42 UTC 2012
Date: Thursday, October 4, 2012 @ 16:53:42
Author: eric
Revision: 167994
archrelease: copy trunk to staging-any
Added:
python-feedparser/repos/staging-any/
python-feedparser/repos/staging-any/PKGBUILD
(from rev 167993, python-feedparser/trunk/PKGBUILD)
----------+
PKGBUILD | 62 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 62 insertions(+)
Copied: python-feedparser/repos/staging-any/PKGBUILD (from rev 167993, python-feedparser/trunk/PKGBUILD)
===================================================================
--- staging-any/PKGBUILD (rev 0)
+++ staging-any/PKGBUILD 2012-10-04 20:53:42 UTC (rev 167994)
@@ -0,0 +1,62 @@
+# $Id$
+# Maintainer: Eric Bélanger <eric at archlinux.org>
+
+pkgbase=python-feedparser
+pkgname=('python2-feedparser' 'python-feedparser' 'python-sgmllib')
+pkgver=5.1.2
+pkgrel=2
+pkgdesc="Parse RSS and Atom feeds in Python"
+arch=('any')
+url="http://code.google.com/p/feedparser/"
+license=('custom')
+makedepends=('python' 'python2' 'libxml2' 'python2-distribute' 'python-distribute')
+source=(http://feedparser.googlecode.com/files/feedparser-${pkgver}.tar.bz2)
+md5sums=('9f88692c7c1af1d47839eb2025984975')
+
+build() {
+ cd "${srcdir}"
+ chmod 644 feedparser-${pkgver}/feedparser/feedparser.egg-info/*
+ cp -r feedparser-${pkgver} feedparser-${pkgver}-python2
+ cp -r feedparser-${pkgver} feedparser-${pkgver}-python
+ cp -r feedparser-${pkgver} feedparser-${pkgver}-sgmllib
+
+ cd feedparser-${pkgver}-python2
+ sed -i 's#env python$#env python2#' feedparser/feedparser.py
+ cd ..
+
+ cd feedparser-${pkgver}-python
+ 2to3 -w feedparser/feedparser.py feedparser/feedparsertest.py
+ cd ..
+
+ cd feedparser-${pkgver}-sgmllib
+ python /usr/lib/python3.3/compileall.py feedparser/sgmllib3.py
+}
+
+package_python2-feedparser() {
+ depends=('python2' 'libxml2' )
+ pkgdesc="Parse RSS and Atom feeds in Python2"
+
+ cd "${srcdir}/feedparser-${pkgver}-python2"
+ python2 setup.py install --root="${pkgdir}"
+ install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/license"
+}
+
+package_python-feedparser() {
+ depends=('libxml2' 'python-sgmllib')
+
+ cd "${srcdir}/feedparser-${pkgver}-python"
+ python setup.py install --root="${pkgdir}"
+ install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/license"
+}
+
+package_python-sgmllib() {
+ depends=('python')
+ pkgdesc="Port of sgmllib to python-3"
+ license=('PSF')
+
+ cd "${srcdir}/feedparser-${pkgver}-sgmllib"
+ install -Dm644 feedparser/sgmllib3.py \
+ "${pkgdir}/usr/lib/python3.3/site-packages/sgmllib.py"
+ install -Dm644 feedparser/__pycache__/sgmllib3.cpython-33.pyc \
+ "${pkgdir}/usr/lib/python3.3/site-packages/__pycache__/sgmllib.cpython-33.pyc"
+}
More information about the arch-commits
mailing list