[arch-commits] Commit in lib32-qt4/repos (2 files)

[Evangelos Foutras]

    Date: Tuesday, April 30, 2013 @ 18:12:44
  Author: foutrelis
Revision: 89631

archrelease: copy trunk to multilib-staging-x86_64

Added:
  lib32-qt4/repos/multilib-staging-x86_64/
  lib32-qt4/repos/multilib-staging-x86_64/PKGBUILD
    (from rev 89630, lib32-qt4/trunk/PKGBUILD)

----------+
 PKGBUILD |   89 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 89 insertions(+)

Copied: lib32-qt4/repos/multilib-staging-x86_64/PKGBUILD (from rev 89630, lib32-qt4/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-staging-x86_64/PKGBUILD	2013-04-30 16:12:44 UTC (rev 89631)
@@ -0,0 +1,89 @@
+# $Id: PKGBUILD 80785 2012-12-03 16:17:19Z bluewind $
+# Maintainer: Florian Pritz <flo at xssn.at>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Pierre Schmitz <pierre at archlinux.de>
+
+_pkgbasename=qt4
+pkgname=lib32-$_pkgbasename
+pkgver=4.8.4
+pkgrel=5
+pkgdesc='A cross-platform application and UI framework (32-bit)'
+arch=('x86_64')
+url='http://qt-project.org/'
+license=('GPL3' 'LGPL')
+depends=(lib32-{fontconfig,sqlite3,alsa-lib,glib2,dbus-core,openssl}
+         lib32-lib{png,tiff,mng,gl,sm,xrandr,xv,xi} $_pkgbasename)
+optdepends=('lib32-libxinerama: Xinerama support'
+            'lib32-libxcursor: Xcursor support'
+            'lib32-libxfixes: Xfixes support')
+makedepends=(cups gcc-multilib lib32-{mesa,libcups,libxfixes,gtk2})
+options=('!libtool')
+provides=(lib32-qtwebkit)
+replaces=(lib32-qtwebkit 'lib32-qt<=4.8.4')
+conflicts=(lib32-qtwebkit lib32-qt)
+_pkgfqn="qt-everywhere-opensource-src-${pkgver}"
+source=("http://releases.qt-project.org/qt4/source/${_pkgfqn}.tar.gz")
+md5sums=('89c5ecba180cae74c66260ac732dc5cb')
+
+build() {
+  cd $srcdir/$_pkgfqn
+
+  export QT4DIR=$srcdir/$_pkgfqn
+  export LD_LIBRARY_PATH=${QT4DIR}/lib:${LD_LIBRARY_PATH}
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  # some of those are likely unnecessary, but I'm too lazy to find and remove them
+  sed -i "/^QMAKE_LINK\s/s|g++|g++ -m32|g" mkspecs/common/g++-base.conf
+  sed -i "s|-O2|${CXXFLAGS} -m32|" mkspecs/common/g++-base.conf
+  sed -i "s|-O2|${CXXFLAGS} -m32|" mkspecs/common/gcc-base.conf
+  sed -i "/^QMAKE_LFLAGS_RPATH/s| -Wl,-rpath,||g" mkspecs/common/gcc-base-unix.conf
+  sed -i "/^QMAKE_LFLAGS\s/s|+=|+= ${LDFLAGS} -m32|g" mkspecs/common/gcc-base.conf
+  sed -i "s|-Wl,-O1|-m32 -Wl,-O1|" mkspecs/common/g++-unix.conf
+  sed -e "s|-O2|$CXXFLAGS -m32|" \
+      -e "/^QMAKE_RPATH/s| -Wl,-rpath,||g" \
+      -e "/^QMAKE_LINK\s/s|g++|g++ -m32|g" \
+      -e "/^QMAKE_LFLAGS\s/s|+=|+= $LDFLAGS|g" \
+      -i mkspecs/common/g++.conf
+
+  ./configure -confirm-license -opensource -v -platform linux-g++-32 \
+    -prefix /usr \
+    -libdir /usr/lib32 \
+    -plugindir /usr/lib32/qt/plugins \
+    -importdir /usr/lib32/qt/imports \
+    -datadir /usr/share/qt \
+    -translationdir /usr/share/qt/translations \
+    -sysconfdir /etc \
+    -system-sqlite \
+    -no-phonon \
+    -no-phonon-backend \
+    -webkit \
+    -graphicssystem raster \
+    -openssl-linked \
+    -nomake demos \
+    -nomake examples \
+    -nomake docs \
+    -nomake tools \
+    -optimized-qmake \
+    -no-rpath \
+    -dbus-linked \
+    -reduce-relocations \
+    -no-openvg
+
+  make
+}
+
+package() {
+  cd $srcdir/$_pkgfqn
+  make INSTALL_ROOT=$pkgdir install
+
+  # Fix wrong path in pkgconfig files
+  find ${pkgdir}/usr/lib32/pkgconfig -type f -name '*.pc' \
+    -exec perl -pi -e "s, -L${srcdir}/?\S+,,g" {} \;
+  # Fix wrong path in prl files
+  find ${pkgdir}/usr/lib32 -type f -name '*.prl' \
+    -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d;s/\(QMAKE_PRL_LIBS =\).*/\1/' {} \;
+
+  rm -rf "${pkgdir}"/usr/{include,share,bin,tests}
+  mkdir -p "$pkgdir/usr/share/licenses"
+  ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
+}