[arch-commits] Commit in (4 files)

[Andrea Scarpino]

    Date: Saturday, December 21, 2013 @ 14:54:55
  Author: andrea
Revision: 202374

Plasma2

Added:
  plasma-framework/
  plasma-framework/repos/
  plasma-framework/trunk/
  plasma-framework/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: plasma-framework/trunk/PKGBUILD
===================================================================
--- plasma-framework/trunk/PKGBUILD	                        (rev 0)
+++ plasma-framework/trunk/PKGBUILD	2013-12-21 13:54:55 UTC (rev 202374)
@@ -0,0 +1,45 @@
+# $Id
+# Maintainer: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=plasma-framework
+pkgver=plasma2tp.r3.ga3a9dff
+pkgrel=1
+pkgdesc='Plasma library and runtime components based upon KF5 and Qt5'
+arch=('i686' 'x86_64')
+url='https://projects.kde.org/projects/playground/libs/plasma-framework'
+license=('LGPL')
+depends=('qt5-quick1' 'kidletime' 'kitemmodels'
+         'kwidgetsaddons' 'kcodecs' 'karchive' 'solid' 'threadweaver'
+         'kglobalaccel' 'kauth' 'kwallet-framework' 'kguiaddons'
+         'kconfigwidgets' 'kitemviews' 'knotifications' 'kiconthemes'
+         'kcompletion' 'kjobwidgets' 'sonnet' 'ktextwidgets' 'kxmlgui'
+         'kbookmarks' 'kdeclarative' 'kunitconversion' 'kparts' 'kross'
+         'kdnssd-framework' 'kde4support' 'kdesignerplugin' 'kinit'
+         'kactivities-frameworks')
+makedepends=('extra-cmake-modules' 'git' 'qt5-tools')
+source=('git://anongit.kde.org/plasma-framework.git#tag=plasma2tp')
+md5sums=('SKIP')
+
+pkgver() {
+  cd plasma-framework
+  git describe --long | sed -E 's/([^-]*-g)/r\1/;s/-/./g'
+}
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../plasma-framework \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/opt/kf5 \
+    -DLIB_INSTALL_DIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="${pkgdir}" install
+}


Property changes on: plasma-framework/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property