[arch-commits] Commit in (8 files)

Massimiliano Torromeo mtorromeo at nymeria.archlinux.org
Thu Feb 21 13:50:48 UTC 2013


    Date: Thursday, February 21, 2013 @ 14:50:48
  Author: mtorromeo
Revision: 84666

Move python{,2}-oauthlib and dependencies to [community]

Added:
  python-oauthlib/
  python-oauthlib/repos/
  python-oauthlib/trunk/
  python-oauthlib/trunk/PKGBUILD
  python-rsa/
  python-rsa/repos/
  python-rsa/trunk/
  python-rsa/trunk/PKGBUILD

--------------------------------+
 python-oauthlib/trunk/PKGBUILD |   44 +++++++++++++++++++++++++++++++++++++
 python-rsa/trunk/PKGBUILD      |   46 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 90 insertions(+)

Added: python-oauthlib/trunk/PKGBUILD
===================================================================
--- python-oauthlib/trunk/PKGBUILD	                        (rev 0)
+++ python-oauthlib/trunk/PKGBUILD	2013-02-21 13:50:48 UTC (rev 84666)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+
+pkgbase=python-oauthlib
+pkgname=(python-oauthlib python2-oauthlib)
+pkgver=0.3.7
+pkgrel=1
+_libname=oauthlib
+pkgdesc="A generic, spec-compliant, thorough implementation of the OAuth request-signing logic"
+arch=(any)
+url="https://github.com/idangazit/oauthlib"
+license=('BSD')
+source=(http://pypi.python.org/packages/source/${_libname:0:1}/$_libname/$_libname-$pkgver.tar.gz)
+makedepends=(python-distribute python2-distribute)
+
+build() {
+	cd "$srcdir/$_libname-$pkgver"
+	
+	rm -rf ../buildpy3; mkdir ../buildpy3
+	python setup.py build -b ../buildpy3
+	
+	rm -rf ../buildpy2; mkdir ../buildpy2
+	python2 setup.py build -b ../buildpy2
+}
+
+package_python-oauthlib() {
+	depends=(python-rsa)
+	
+	cd "$srcdir/$_libname-$pkgver"
+	rm -rf build; ln -s ../buildpy3 build
+	python setup.py install --skip-build -O1 --root="$pkgdir"
+	install -m0644 -D "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-oauthlib() {
+	depends=(python2-rsa)
+	
+	cd "$srcdir/$_libname-$pkgver"
+	rm -rf build; ln -s ../buildpy2 build
+	python2 setup.py install --skip-build -O1 --root="$pkgdir"
+	install -m0644 -D "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+sha256sums=('12b8fb9fa02a531c412bdc0fcb3a214e3da8c4075f19d6ca2c6d1a3636d2a000')


Property changes on: python-oauthlib/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: python-rsa/trunk/PKGBUILD
===================================================================
--- python-rsa/trunk/PKGBUILD	                        (rev 0)
+++ python-rsa/trunk/PKGBUILD	2013-02-21 13:50:48 UTC (rev 84666)
@@ -0,0 +1,46 @@
+# $Id$
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+
+pkgbase=python-rsa
+pkgname=(python-rsa python2-rsa)
+pkgver=3.1.1
+pkgrel=2
+_libname=rsa
+pkgdesc="Pure-Python RSA implementation"
+arch=(any)
+url="http://stuvel.eu/rsa"
+license=('BSD')
+source=(http://pypi.python.org/packages/source/r/$_libname/$_libname-$pkgver.tar.gz)
+makedepends=(python-distribute python2-distribute)
+
+build() {
+	cd "$srcdir/$_libname-$pkgver"
+	
+	rm -rf ../buildpy3; mkdir ../buildpy3
+	python setup.py build -b ../buildpy3
+	
+	rm -rf ../buildpy2; mkdir ../buildpy2
+	python2 setup.py build -b ../buildpy2
+}
+
+package_python-rsa() {
+	depends=(python-pyasn1)
+	
+	cd "$srcdir/$_libname-$pkgver"
+	rm -rf build; ln -s ../buildpy3 build
+	python setup.py install --skip-build -O1 --root="$pkgdir"
+	install -m0644 -D "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-rsa() {
+	depends=(python2-pyasn1)
+	
+	cd "$srcdir/$_libname-$pkgver"
+	rm -rf build; ln -s ../buildpy2 build
+	python2 setup.py install --skip-build -O1 --root="$pkgdir"
+	install -m0644 -D "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+	
+	find "$pkgdir/usr/bin" -type f | while read f; do mv "$f" "$f"2; done
+}
+
+sha256sums=('ed83fe80602077bcbf91d14e41558c751d76527c7b88d44394e1e2900fddb7ba')


Property changes on: python-rsa/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property



More information about the arch-commits mailing list