[arch-commits] Commit in django/repos (testing-any testing-any/PKGBUILD)

[Dan McGee]

    Date: Wednesday, February 27, 2013 @ 01:41:58
  Author: dan
Revision: 178770

archrelease: copy trunk to testing-any

Added:
  django/repos/testing-any/
  django/repos/testing-any/PKGBUILD
    (from rev 178769, django/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: django/repos/testing-any/PKGBUILD (from rev 178769, django/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD	                        (rev 0)
+++ testing-any/PKGBUILD	2013-02-27 00:41:58 UTC (rev 178770)
@@ -0,0 +1,38 @@
+# $Id$
+# Maintainer: Dan McGee <dan at archlinux.org>
+# Contributor: Shahar Weiss <sweiss4 at gmx.net>
+
+pkgname=django
+pkgver=1.5
+pkgrel=1
+pkgdesc="A high-level Python Web framework that encourages rapid development and clean design"
+arch=('any')
+license=('BSD')
+url="http://www.djangoproject.com/"
+depends=('python2')
+makedepends=('python2-distribute')
+optdepends=('mysql-python: for MySQL backend'
+            'python2-psycopg2: for PostgreSQL backend')
+source=("https://www.djangoproject.com/m/releases/${pkgver:0:3}/Django-$pkgver.tar.gz")
+md5sums=('fac09e1e0f11bb83bb187d652a9be967')
+sha256sums=('078bf8f8ab025ed79e41ed5cee145a64dffea638eb5c2928c8cd106720824416')
+
+build() {
+  cd "$srcdir/Django-$pkgver"
+  python2 setup.py build
+}
+
+package() {
+  cd "$srcdir/Django-$pkgver"
+  python2 setup.py install --root="$pkgdir" --optimize=1
+
+  install -Dm644 extras/django_bash_completion \
+    "$pkgdir"/usr/share/bash-completion/completions/django-admin.py
+  ln -s django-admin.py \
+    "$pkgdir"/usr/share/bash-completion/completions/manage.py
+
+  find "$pkgdir"/usr/lib/python2.7/site-packages/django/ -name '*.py' | \
+    xargs sed -i "s|#!/usr/bin/env python$|#!/usr/bin/env python2|"
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}