[arch-commits] Commit in xdg-utils/repos (testing-any testing-any/PKGBUILD)

[Bartłomiej Piotrowski]

    Date: Sunday, July 28, 2013 @ 20:26:46
  Author: bpiotrowski
Revision: 191637

archrelease: copy trunk to testing-any

Added:
  xdg-utils/repos/testing-any/
  xdg-utils/repos/testing-any/PKGBUILD
    (from rev 191636, xdg-utils/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: xdg-utils/repos/testing-any/PKGBUILD (from rev 191636, xdg-utils/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD	                        (rev 0)
+++ testing-any/PKGBUILD	2013-07-28 18:26:46 UTC (rev 191637)
@@ -0,0 +1,42 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=xdg-utils
+pkgver=1.1.0.git20130520
+pkgrel=1
+pkgdesc="Command line tools that assist applications with a variety of desktop integration tasks"
+arch=('any')
+url="http://portland.freedesktop.org/"
+license=('MIT')
+depends=('sh' 'xorg-xset') # xset needed inside xdg-screensaver
+makedepends=('docbook-xsl' 'lynx' 'xmlto' 'git')
+optdepends=('kdebase-runtime: for KDE support in xdg-open'
+            'libgnome: for GNOME support in xdg-open'
+            'exo: for Xfce support in xdg-open'
+            'xorg-xprop: for Xfce support in xdg-open'
+            'pcmanfm: for LXDE support in xdg-open'
+            'perl-file-mimeinfo: for generic support in xdg-open')
+source=(git://anongit.freedesktop.org/xdg/xdg-utils#commit=2373d9b2b7)
+md5sums=('SKIP')
+
+pkgver() {
+	cd xdg-utils
+	echo "1.1.0.git$(git log -1 --format="%cd" --date=short | sed 's|-||g')"
+}
+
+build() {
+	cd xdg-utils
+	./configure --prefix=/usr --mandir=/usr/share/man
+	make scripts-clean -C scripts # needed if it's a git snapshot
+	make man scripts -C scripts # needed if it's a git snapshot
+#	make # for release builds
+}
+
+package() {
+	cd xdg-utils
+	make DESTDIR="${pkgdir}" install
+	install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+	
+	# install empty directory to prevent xdg-desktop-menu install *.desktop to fail, see FS#33316
+	install -dm755 $pkgdir/usr/share/desktop-directories
+}