[arch-commits] Commit in harfbuzz/trunk (PKGBUILD)

[Jan Steffens]

    Date: Friday, June 7, 2013 @ 06:30:36
  Author: heftig
Revision: 187848

0.9.18. icu split out

Modified:
  harfbuzz/trunk/PKGBUILD

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++------------------
 1 file changed, 35 insertions(+), 18 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2013-06-07 04:11:56 UTC (rev 187847)
+++ PKGBUILD	2013-06-07 04:30:36 UTC (rev 187848)
@@ -1,29 +1,46 @@
 # $Id$
 # Maintainer: Jan de Groot <jgc at archlinux.org>
 
-pkgname=harfbuzz
-pkgver=0.9.17
-pkgrel=2
-pkgdesc="OpenType text shaping engine."
-arch=('i686' 'x86_64')
+pkgbase=(harfbuzz)
+pkgname=(harfbuzz harfbuzz-icu)
+pkgver=0.9.18
+pkgrel=1
+pkgdesc="OpenType text shaping engine"
+arch=(i686 x86_64)
 url="http://www.freedesktop.org/wiki/Software/HarfBuzz"
-license=('MIT')
-depends=('icu' 'glib2' 'freetype2' 'graphite>=1.2.0')
-makedepends=('icu' 'cairo' 'glib2' 'freetype2')
-optdepends=('cairo: hb-view program')
+license=(MIT)
+makedepends=(glib2 freetype2 graphite cairo icu)
 options=(!libtool)
-source=(http://www.freedesktop.org/software/harfbuzz/release/${pkgname}-${pkgver}.tar.bz2)
-sha256sums=('a4773003512035cb5c559de23e1d53f292bcb0212f023b540c4dc695b39690ed')
+source=(http://www.freedesktop.org/software/harfbuzz/release/${pkgbase}-${pkgver}.tar.bz2)
+sha256sums=('fef0fbbc6d6492cb4074a5e26a699d87d88bef8adc25dda62af6077735a7d908')
 
 build() {
-  cd ${pkgname}-${pkgver}
-
-  ./configure --prefix=/usr
+  cd $pkgbase-$pkgver
+  ./configure --prefix=/usr \
+    --with-glib --with-freetype --with-cairo --with-icu --with-graphite2
   make
 }
 
-package() {
-  cd ${pkgname}-${pkgver}
-  make DESTDIR="${pkgdir}" install
-  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/harfbuzz/COPYING"
+package_harfbuzz() {
+  depends=(glib2 freetype2 graphite)
+  optdepends=('cairo: hb-view program')
+
+  cd $pkgbase-$pkgver
+  make DESTDIR="$pkgdir" install
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/harfbuzz/COPYING"
+
+# Split harfbuzz-icu
+  mkdir -p ../hb-icu/usr/{include/harfbuzz,lib/pkgconfig}; cd ../hb-icu
+  mv "$pkgdir"/usr/lib/libharfbuzz-icu* ./usr/lib
+  mv "$pkgdir"/usr/lib/pkgconfig/harfbuzz-icu.pc ./usr/lib/pkgconfig
+  mv "$pkgdir"/usr/include/harfbuzz/hb-icu.h ./usr/include/harfbuzz
 }
+
+package_harfbuzz-icu(){
+  pkgdesc="$pkgdesc (ICU integration)"
+  depends=(harfbuzz icu)
+
+  mv hb-icu/* "$pkgdir"
+
+  install -Dm644 $pkgbase-$pkgver/COPYING "$pkgdir/usr/share/licenses/harfbuzz-icu/COPYING"
+}