[arch-commits] Commit in pdflib-lite (trunk trunk/PKGBUILD)
Connor Behan
cbehan at nymeria.archlinux.org
Wed Jun 19 07:37:56 UTC 2013
Date: Wednesday, June 19, 2013 @ 09:37:55
Author: cbehan
Revision: 92915
upgpkg: pdflib-lite 7.0.5p3-2
Update to 7.0.5p3-2
Added:
pdflib-lite/trunk/
pdflib-lite/trunk/PKGBUILD
----------+
PKGBUILD | 49 +++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 49 insertions(+)
Added: trunk/PKGBUILD
===================================================================
--- trunk/PKGBUILD (rev 0)
+++ trunk/PKGBUILD 2013-06-19 07:37:55 UTC (rev 92915)
@@ -0,0 +1,49 @@
+# Maintainer: Connor Behan <connor.behan at gmail.com>
+# Contributor: Olivier Mehani <shtrom-arch at ssji.net>
+
+pkgname=pdflib-lite
+_pkgnamecaps=PDFlib-Lite
+pkgver=7.0.5p3
+_basepkgver=${pkgver/p*/}
+pkgrel=2
+pkgdesc="PDF manipulation library."
+url="http://www.pdflib.com"
+arch=(i686 x86_64)
+depends=('glibc')
+provides=('pdflib')
+source=(http://www.pdflib.com/binaries/PDFlib/${_basepkgver//./}/${_pkgnamecaps}-${pkgver}.tar.gz http://www.pdflib.com/fileadmin/pdflib/pdf/license/PDFlib-Lite-license.pdf)
+license=(custom:pdflib-lite)
+
+build() {
+ cd "$srcdir"/$_pkgnamecaps-$pkgver
+ ./configure --prefix=/usr
+ make
+}
+
+package() {
+ cd "$srcdir"/$_pkgnamecaps-$pkgver
+ make prefix="$pkgdir"/usr install
+
+ ## Copy files required by the license
+ # Documentation
+ mkdir -p "$pkgdir"/usr/share/pdflib-lite/doc
+ cp ./doc/pdflib/* "$pkgdir"/usr/share/pdflib-lite/doc
+
+ # License
+ mkdir -p "$pkgdir"/usr/share/licenses/pdflib-lite
+ cp -H ../PDFlib-Lite-license.pdf "$pkgdir"/usr/share/licenses/pdflib-lite/LICENSE.pdf
+
+ # Examples
+ make -C ./bind/pdflib clean
+ cp -R ./bind/pdflib/{c,cpp,java} "$pkgdir"/usr/share/pdflib-lite
+ find "$pkgdir"/usr/share/pdflib-lite \( \
+ -name Makefile \
+ -o -name *.dsp \
+ -o -name *.dsw \
+ -o -name *.sln \
+ -o -name *.vcproj \
+ \) -exec rm {} \;
+}
+
+md5sums=('371d332d610a8b21a542bb7a2bdaf954'
+ '2f3f9cc20199aad91b33dc26cdcbbab4')
Property changes on: pdflib-lite/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list