[arch-commits] Commit in python2/repos (4 files)
Stéphane Gaudreault
stephane at nymeria.archlinux.org
Sun May 12 16:29:50 UTC 2013
Date: Sunday, May 12, 2013 @ 18:29:50
Author: stephane
Revision: 185267
archrelease: copy trunk to testing-i686, testing-x86_64
Added:
python2/repos/testing-i686/
python2/repos/testing-i686/PKGBUILD
(from rev 185266, python2/trunk/PKGBUILD)
python2/repos/testing-x86_64/
python2/repos/testing-x86_64/PKGBUILD
(from rev 185266, python2/trunk/PKGBUILD)
-------------------------+
testing-i686/PKGBUILD | 88 ++++++++++++++++++++++++++++++++++++++++++++++
testing-x86_64/PKGBUILD | 88 ++++++++++++++++++++++++++++++++++++++++++++++
2 files changed, 176 insertions(+)
Copied: python2/repos/testing-i686/PKGBUILD (from rev 185266, python2/trunk/PKGBUILD)
===================================================================
--- testing-i686/PKGBUILD (rev 0)
+++ testing-i686/PKGBUILD 2013-05-12 16:29:50 UTC (rev 185267)
@@ -0,0 +1,88 @@
+# $Id$
+# Maintainer: Stéphane Gaudreault <stephane at archlinux.org>
+# Contributer: Allan McRae <allan at archlinux.org>
+# Contributer: Jason Chu <jason at archlinux.org>
+
+pkgname=python2
+pkgver=2.7.5
+pkgrel=1
+_pybasever=2.7
+pkgdesc="A high-level scripting language"
+arch=('i686' 'x86_64')
+license=('PSF')
+url="http://www.python.org/"
+depends=('bzip2' 'gdbm' 'openssl' 'zlib' 'expat' 'sqlite' 'libffi')
+makedepends=('tk>=8.6.0' 'bluez')
+optdepends=('tk: for IDLE')
+conflicts=('python<3')
+options=('!makeflags')
+source=(http://www.python.org/ftp/python/${pkgver%rc?}/Python-${pkgver}.tar.xz)
+sha1sums=('b7389791f789625c2ba9d897aa324008ff482daf')
+
+build() {
+ cd "${srcdir}/Python-${pkgver}"
+
+ # Temporary workaround for FS#22322
+ # See http://bugs.python.org/issue10835 for upstream report
+ sed -i "/progname =/s/python/python${_pybasever}/" Python/pythonrun.c
+
+ # Enable built-in SQLite module to load extensions (fix FS#22122)
+ sed -i "/SQLITE_OMIT_LOAD_EXTENSION/d" setup.py
+
+ # FS#23997
+ sed -i -e "s|^#.* /usr/local/bin/python|#!/usr/bin/python2|" Lib/cgi.py
+
+ sed -i "s/python2.3/python2/g" Lib/distutils/tests/test_build_scripts.py \
+ Lib/distutils/tests/test_install_scripts.py Tools/scripts/gprof2html.py
+
+ # Ensure that we are using the system copy of various libraries (expat, zlib and libffi),
+ # rather than copies shipped in the tarball
+ rm -r Modules/expat
+ rm -r Modules/zlib
+ rm -r Modules/_ctypes/{darwin,libffi}*
+
+ export OPT="${CFLAGS}"
+ ./configure --prefix=/usr --enable-shared --with-threads --enable-ipv6 \
+ --enable-unicode=ucs4 --with-system-expat --with-system-ffi \
+ --with-dbmliborder=gdbm:ndbm
+
+ make
+}
+
+package() {
+ cd "${srcdir}/Python-${pkgver}"
+ make DESTDIR="${pkgdir}" altinstall maninstall
+
+ rm "${pkgdir}"/usr/share/man/man1/python.1
+
+ ln -sf python${_pybasever} "${pkgdir}"/usr/bin/python2
+ ln -sf python${_pybasever}-config "${pkgdir}"/usr/bin/python2-config
+ ln -sf python${_pybasever}.1 "${pkgdir}"/usr/share/man/man1/python2.1
+
+ # FS#33954
+ ln -sf python-${_pybasever}.pc "${pkgdir}"/usr/lib/pkgconfig/python2.pc
+
+ ln -sf ../../libpython${_pybasever}.so "${pkgdir}"/usr/lib/python${_pybasever}/config/libpython${_pybasever}.so
+
+ mv "${pkgdir}"/usr/bin/smtpd.py "${pkgdir}"/usr/lib/python${_pybasever}/
+
+ # some useful "stuff"
+ install -dm755 "${pkgdir}"/usr/lib/python${_pybasever}/Tools/{i18n,scripts}
+ install -m755 Tools/i18n/{msgfmt,pygettext}.py "${pkgdir}"/usr/lib/python${_pybasever}/Tools/i18n/
+ install -m755 Tools/scripts/{README,*py} "${pkgdir}"/usr/lib/python${_pybasever}/Tools/scripts/
+
+ # fix conflicts with python
+ mv "${pkgdir}"/usr/bin/idle{,2}
+ mv "${pkgdir}"/usr/bin/pydoc{,2}
+ mv "${pkgdir}"/usr/bin/2to3{,-2.7}
+
+ # clean up #!s
+ find "${pkgdir}"/usr/lib/python${_pybasever}/ -name '*.py' | \
+ xargs sed -i "s|#[ ]*![ ]*/usr/bin/env python$|#!/usr/bin/env python2|"
+
+ # clean-up reference to build directory
+ sed -i "s#${srcdir}/Python-${pkgver}:##" "${pkgdir}"/usr/lib/python${_pybasever}/config/Makefile
+
+ # license
+ install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}
Copied: python2/repos/testing-x86_64/PKGBUILD (from rev 185266, python2/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2013-05-12 16:29:50 UTC (rev 185267)
@@ -0,0 +1,88 @@
+# $Id$
+# Maintainer: Stéphane Gaudreault <stephane at archlinux.org>
+# Contributer: Allan McRae <allan at archlinux.org>
+# Contributer: Jason Chu <jason at archlinux.org>
+
+pkgname=python2
+pkgver=2.7.5
+pkgrel=1
+_pybasever=2.7
+pkgdesc="A high-level scripting language"
+arch=('i686' 'x86_64')
+license=('PSF')
+url="http://www.python.org/"
+depends=('bzip2' 'gdbm' 'openssl' 'zlib' 'expat' 'sqlite' 'libffi')
+makedepends=('tk>=8.6.0' 'bluez')
+optdepends=('tk: for IDLE')
+conflicts=('python<3')
+options=('!makeflags')
+source=(http://www.python.org/ftp/python/${pkgver%rc?}/Python-${pkgver}.tar.xz)
+sha1sums=('b7389791f789625c2ba9d897aa324008ff482daf')
+
+build() {
+ cd "${srcdir}/Python-${pkgver}"
+
+ # Temporary workaround for FS#22322
+ # See http://bugs.python.org/issue10835 for upstream report
+ sed -i "/progname =/s/python/python${_pybasever}/" Python/pythonrun.c
+
+ # Enable built-in SQLite module to load extensions (fix FS#22122)
+ sed -i "/SQLITE_OMIT_LOAD_EXTENSION/d" setup.py
+
+ # FS#23997
+ sed -i -e "s|^#.* /usr/local/bin/python|#!/usr/bin/python2|" Lib/cgi.py
+
+ sed -i "s/python2.3/python2/g" Lib/distutils/tests/test_build_scripts.py \
+ Lib/distutils/tests/test_install_scripts.py Tools/scripts/gprof2html.py
+
+ # Ensure that we are using the system copy of various libraries (expat, zlib and libffi),
+ # rather than copies shipped in the tarball
+ rm -r Modules/expat
+ rm -r Modules/zlib
+ rm -r Modules/_ctypes/{darwin,libffi}*
+
+ export OPT="${CFLAGS}"
+ ./configure --prefix=/usr --enable-shared --with-threads --enable-ipv6 \
+ --enable-unicode=ucs4 --with-system-expat --with-system-ffi \
+ --with-dbmliborder=gdbm:ndbm
+
+ make
+}
+
+package() {
+ cd "${srcdir}/Python-${pkgver}"
+ make DESTDIR="${pkgdir}" altinstall maninstall
+
+ rm "${pkgdir}"/usr/share/man/man1/python.1
+
+ ln -sf python${_pybasever} "${pkgdir}"/usr/bin/python2
+ ln -sf python${_pybasever}-config "${pkgdir}"/usr/bin/python2-config
+ ln -sf python${_pybasever}.1 "${pkgdir}"/usr/share/man/man1/python2.1
+
+ # FS#33954
+ ln -sf python-${_pybasever}.pc "${pkgdir}"/usr/lib/pkgconfig/python2.pc
+
+ ln -sf ../../libpython${_pybasever}.so "${pkgdir}"/usr/lib/python${_pybasever}/config/libpython${_pybasever}.so
+
+ mv "${pkgdir}"/usr/bin/smtpd.py "${pkgdir}"/usr/lib/python${_pybasever}/
+
+ # some useful "stuff"
+ install -dm755 "${pkgdir}"/usr/lib/python${_pybasever}/Tools/{i18n,scripts}
+ install -m755 Tools/i18n/{msgfmt,pygettext}.py "${pkgdir}"/usr/lib/python${_pybasever}/Tools/i18n/
+ install -m755 Tools/scripts/{README,*py} "${pkgdir}"/usr/lib/python${_pybasever}/Tools/scripts/
+
+ # fix conflicts with python
+ mv "${pkgdir}"/usr/bin/idle{,2}
+ mv "${pkgdir}"/usr/bin/pydoc{,2}
+ mv "${pkgdir}"/usr/bin/2to3{,-2.7}
+
+ # clean up #!s
+ find "${pkgdir}"/usr/lib/python${_pybasever}/ -name '*.py' | \
+ xargs sed -i "s|#[ ]*![ ]*/usr/bin/env python$|#!/usr/bin/env python2|"
+
+ # clean-up reference to build directory
+ sed -i "s#${srcdir}/Python-${pkgver}:##" "${pkgdir}"/usr/lib/python${_pybasever}/config/Makefile
+
+ # license
+ install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}
More information about the arch-commits
mailing list