[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Tuesday, November 5, 2013 @ 03:18:52
  Author: fyan
Revision: 100478

addpkg: python-anyjson 0.3.3-5

Added:
  python2-anyjson/
  python2-anyjson/repos/
  python2-anyjson/trunk/
  python2-anyjson/trunk/PKGBUILD

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Added: python2-anyjson/trunk/PKGBUILD
===================================================================
--- python2-anyjson/trunk/PKGBUILD	                        (rev 0)
+++ python2-anyjson/trunk/PKGBUILD	2013-11-05 02:18:52 UTC (rev 100478)
@@ -0,0 +1,39 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at gmail.com>
+# Contributor: Benjamin A. Shelton <zancarius at gmail.com>
+# Contributor: p2k <Patrick.Schneider at uni-ulm.de>
+
+_pypiname=anyjson
+pkgbase=python-$_pypiname
+pkgname=("python-$_pypiname" "python2-$_pypiname")
+pkgver=0.3.3
+pkgrel=5
+pkgdesc="Wraps the best available JSON implementation available in a common interface"
+arch=(any)
+url="http://pypi.python.org/pypi/$_pypiname"
+license=('BSD')
+makedepends=('python-setuptools' 'python2-setuptools')
+source=("http://pypi.python.org/packages/source/a/$_pypiname/$_pypiname-${pkgver}.tar.gz")
+md5sums=('2ea28d6ec311aeeebaf993cb3008b27c')
+
+prepare() {
+  cp -r "$_pypiname-${pkgver}" "python2-$_pypiname-${pkgver}"
+}
+
+package_python-anyjson() {
+  depends=('python')
+
+  cd "$_pypiname-${pkgver}"
+  python setup.py install --root="${pkgdir}/" --optimize=1
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-anyjson() {
+  depends=('python2')
+
+  cd "python2-$_pypiname-${pkgver}"
+  python2 setup.py install --root="${pkgdir}/" --optimize=1
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}


Property changes on: python2-anyjson/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property