[arch-commits] Commit in (6 files)

[Alexander Rødseth]

    Date: Wednesday, November 6, 2013 @ 13:00:27
  Author: arodseth
Revision: 100587

Moving prolog to [community]

Added:
  swi-prolog/
  swi-prolog/repos/
  swi-prolog/repos/community-i686/
  swi-prolog/repos/community-x86_64/
  swi-prolog/trunk/
  swi-prolog/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: swi-prolog/trunk/PKGBUILD
===================================================================
--- swi-prolog/trunk/PKGBUILD	                        (rev 0)
+++ swi-prolog/trunk/PKGBUILD	2013-11-06 12:00:27 UTC (rev 100587)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Alexander Rødseth <rodseth at gmail.com>
+# Contributor: Jachym Barvinek <jachymb at gmail.com>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: John Proctor <jproctor at prium.net>
+# Contributor: Juergen Hoetzel <juergen at archlinux.org>
+
+pkgname=swi-prolog
+pkgver=6.4.1
+pkgrel=2
+pkgdesc='Prolog environment'
+arch=('x86_64' 'i686')
+url='http://www.swi-prolog.org/'
+license=('GPL' 'LGPL')
+depends=('gmp' 'readline' 'openssl' 'libarchive')
+makedepends=('libxft' 'libjpeg' 'unixodbc' 'libxpm' 'libxinerama')
+optdepends=('unixodbc: for using the odbc4pl library'
+            'libjpeg: for using the pl2xpce library'
+            'libxpm: for using the pl2xpce library'
+            'libxinerama: for using the pl2xpce library'
+            'libxft: for using the pl2xpce library')
+options=('!makeflags')
+source=("http://www.swi-prolog.org/download/stable/src/pl-$pkgver.tar.gz")
+sha256sums=('48439529784a855ce9246419b51ebe5388acc28d1483a947c6a0397c3dc7f8eb')
+
+build() {
+  cd "pl-$pkgver"
+
+  ./configure --prefix=/usr --with-world --enable-shared
+  make
+}
+
+check() {
+  make -C "pl-$pkgver" check || true
+}
+
+package() {
+  make -C "pl-$pkgver" DESTDIR="$pkgdir" install
+
+  # fix https://bugs.archlinux.org/task/20873
+  chmod +x "$pkgdir/usr/lib/swipl-$pkgver/library/dialect/sicstus/swipl-lfr.pl"
+}
+
+# vim:set ts=2 sw=2 et:


Property changes on: swi-prolog/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property