[arch-commits] Commit in (ninja ninja/repos ninja/trunk ninja/trunk/PKGBUILD)

[Anatol Pomozov]

    Date: Saturday, April 5, 2014 @ 23:59:43
  Author: anatolik
Revision: 108866

ninja: add build tool

Added:
  ninja/
  ninja/repos/
  ninja/trunk/
  ninja/trunk/PKGBUILD

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Added: ninja/trunk/PKGBUILD
===================================================================
--- ninja/trunk/PKGBUILD	                        (rev 0)
+++ ninja/trunk/PKGBUILD	2014-04-05 21:59:43 UTC (rev 108866)
@@ -0,0 +1,48 @@
+# $Id$
+# Maintainer: Anatol Pomozov <anatol.pomozov at gmail.com>
+# Contributor: Filip Brcic <brcha at gna.org>
+# Contributor: Mika Fischer <mika.fischer at zoopnet.de>
+# Contributor: Gergely Imreh <imrehgATgmailDOTcom>
+
+pkgname=ninja
+pkgver=1.4.0
+pkgrel=1
+pkgdesc='Small build system with a focus on speed'
+arch=(i686 x86_64)
+url='http://martine.github.io/ninja/'
+license=(Apache)
+depends=(gcc-libs)
+makedepends=(asciidoc python2 re2c python2 emacs-nox)
+checkdepends=(gtest)
+source=(https://github.com/martine/ninja/archive/v$pkgver.zip)
+sha1sums=('5de3dcd1564056f4f350d99f950f581214893a05')
+
+build() {
+  cd ninja-$pkgver
+
+  python2 ./bootstrap.py
+  emacs -Q --batch -f batch-byte-compile misc/ninja-mode.el
+  asciidoc doc/manual.asciidoc
+}
+
+check() {
+  cd ninja-$pkgver
+
+  python2 ./configure.py --with-gtest=/usr/src/gtest
+  ./ninja ninja_test
+  ./ninja_test --gtest_filter=-SubprocessTest.SetWithLots
+}
+
+package() {
+  cd ninja-$pkgver
+
+  install -m755 -D ninja "$pkgdir/usr/bin/ninja"
+  install -m644 -D doc/manual.asciidoc "$pkgdir/usr/share/doc/ninja/manual.asciidoc"
+  install -m644 -D doc/manual.html "$pkgdir/usr/share/doc/ninja/manual.html"
+
+  install -m644 -D misc/ninja-mode.el "$pkgdir/usr/share/emacs/site-lisp/ninja-mode.el"
+  install -m644 -D misc/ninja-mode.elc "$pkgdir/usr/share/emacs/site-lisp/ninja-mode.elc"
+
+  install -m644 -D misc/bash-completion "$pkgdir/usr/share/bash-completion/completions/ninja"
+  install -m644 -D misc/zsh-completion "$pkgdir/usr/share/zsh/site-functions/_ninja"
+}


Property changes on: ninja/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property