[arch-commits] Commit in (4 files)

Felix Yan fyan at archlinux.org
Fri Aug 22 14:41:44 UTC 2014


    Date: Friday, August 22, 2014 @ 16:41:44
  Author: fyan
Revision: 117766

addpkg: python-idna 0.9-1

as new optdepend for python-service-identity

Added:
  python-idna/
  python-idna/repos/
  python-idna/trunk/
  python-idna/trunk/PKGBUILD

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Added: python-idna/trunk/PKGBUILD
===================================================================
--- python-idna/trunk/PKGBUILD	                        (rev 0)
+++ python-idna/trunk/PKGBUILD	2014-08-22 14:41:44 UTC (rev 117766)
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at gmail.com>
+
+pkgbase=python-idna
+pkgname=('python-idna' 'python2-idna')
+pkgver=0.9
+pkgrel=1
+pkgdesc="Internationalized Domain Names in Applications (IDNA)"
+arch=('any')
+license=('BSD')
+url="https://github.com/kjd/idna"
+makedepends=('python-setuptools' 'python2-setuptools')
+source=("http://pypi.python.org/packages/source/i/idna/idna-${pkgver}.tar.gz")
+md5sums=('adeaa25679040dc6f8098a2e2ab6c42d')
+
+prepare() {
+   cp -a idna-${pkgver}{,-python2}
+}
+
+build() {
+   # Build python 3 module
+   cd idna-${pkgver}
+   python setup.py build
+ 
+   # Build python 2 module
+   cd ../idna-${pkgver}-python2
+   python2 setup.py build
+}
+
+check() {
+   # Check python3 module
+   cd "${srcdir}"/idna-${pkgver}
+   python setup.py test
+
+   # Check python2 module
+   cd "${srcdir}"/idna-${pkgver}-python2
+   python2 setup.py test
+}
+ 
+package_python-idna() {
+   depends=('python')
+ 
+   cd idna-${pkgver}
+   python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+   install -Dm644 LICENSE.rst "$pkgdir/usr/share/licenses/$pkgname/LICENSE.rst"
+}
+ 
+package_python2-idna() {
+   depends=('python2')
+ 
+   cd idna-${pkgver}-python2
+   python2 setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+   install -Dm644 LICENSE.rst "$pkgdir/usr/share/licenses/$pkgname/LICENSE.rst"
+}


Property changes on: python-idna/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property



More information about the arch-commits mailing list