[arch-commits] Commit in lib32-libpng/repos (2 files)
Felix Yan
fyan at archlinux.org
Wed Aug 27 06:26:34 UTC 2014
Date: Wednesday, August 27, 2014 @ 08:26:34
Author: fyan
Revision: 117949
archrelease: copy trunk to multilib-testing-x86_64
Added:
lib32-libpng/repos/multilib-testing-x86_64/
lib32-libpng/repos/multilib-testing-x86_64/PKGBUILD
(from rev 117948, lib32-libpng/trunk/PKGBUILD)
----------+
PKGBUILD | 56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 56 insertions(+)
Copied: lib32-libpng/repos/multilib-testing-x86_64/PKGBUILD (from rev 117948, lib32-libpng/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD (rev 0)
+++ multilib-testing-x86_64/PKGBUILD 2014-08-27 06:26:34 UTC (rev 117949)
@@ -0,0 +1,56 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Contributor: dorphell <dorphell at archlinux.org>
+# Contributor: Travis Willard <travis at archlinux.org>
+# Contributor: Douglas Soares de Andrade <douglas at archlinux.org>
+
+_pkgbasename=libpng
+pkgname=lib32-$_pkgbasename
+pkgver=1.6.13
+_apngver=1.6.13
+_libversion=16
+pkgrel=1
+pkgdesc="A collection of routines used to create PNG format graphics files (32-bit)"
+arch=('x86_64')
+url="http://www.libpng.org/pub/png/libpng.html"
+license=('custom')
+depends=('lib32-zlib' $_pkgbasename)
+makedepends=(gcc-multilib)
+options=('!libtool')
+source=("http://downloads.sourceforge.net/sourceforge/${_pkgbasename}/${_pkgbasename}-${pkgver}.tar.xz"{,.asc}
+ "http://downloads.sourceforge.net/sourceforge/libpng-apng/libpng-${_apngver}-apng.patch.gz")
+md5sums=('9822c25466f060142359f80ed142c9e5'
+ 'SKIP'
+ '1ecbf7811d6da8a35ad7d4485df2290a')
+
+build() {
+ export CC="gcc -m32"
+ export CXX="g++ -m32"
+ export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+ cd "${srcdir}/${_pkgbasename}-${pkgver}"
+
+ # Add animated PNG (apng) support
+ # see http://sourceforge.net/projects/libpng-apng/
+ patch -p1 -i "${srcdir}/libpng-${_apngver}-apng.patch"
+
+ ./configure --prefix=/usr --libdir=/usr/lib32 --program-suffix=-32 --disable-static
+ make
+}
+
+package() {
+ cd "${srcdir}/${_pkgbasename}-${pkgver}"
+
+ make DESTDIR="${pkgdir}" install
+
+ cd contrib/pngminus
+ make PNGLIB="-L${pkgdir}/usr/lib32 -lpng" -f makefile.std png2pnm pnm2png
+
+ rm -rf "${pkgdir}"/usr/{include,share}
+
+ rm "$pkgdir/usr/bin/libpng-config"
+ ln -s "libpng${_libversion}-config-32" "$pkgdir/usr/bin/libpng-config-32"
+
+ mkdir -p "$pkgdir/usr/share/licenses"
+ ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
+}
More information about the arch-commits
mailing list