[arch-commits] Commit in (sni-qt sni-qt/repos sni-qt/trunk sni-qt/trunk/PKGBUILD)
Andrea Scarpino
andrea at archlinux.org
Sun Dec 14 16:14:04 UTC 2014
Date: Sunday, December 14, 2014 @ 17:14:04
Author: andrea
Revision: 227604
Move sni-qt from AUR
Added:
sni-qt/
sni-qt/repos/
sni-qt/trunk/
sni-qt/trunk/PKGBUILD
----------+
PKGBUILD | 40 ++++++++++++++++++++++++++++++++++++++++
1 file changed, 40 insertions(+)
Added: sni-qt/trunk/PKGBUILD
===================================================================
--- sni-qt/trunk/PKGBUILD (rev 0)
+++ sni-qt/trunk/PKGBUILD 2014-12-14 16:14:04 UTC (rev 227604)
@@ -0,0 +1,40 @@
+# $Id$
+# Maintainer: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Alcasa Mz <alcasa.mz at gmail.com>
+
+pkgname=sni-qt
+pkgver=0.2.6
+pkgrel=3
+pkgdesc='Qt4 plugin which turns all QSystemTrayIcon into StatusNotifierItems (appindicators)'
+arch=('i686' 'x86_64')
+url='https://launchpad.net/sni-qt'
+license=('GPL')
+depends=('qt4' 'libdbusmenu-qt')
+makedepends=('cmake')
+source=("http://launchpad.net/${pkgname}/trunk/${pkgver}/+download/${pkgname}-${pkgver}.tar.bz2"
+ 'sni-qt.conf')
+md5sums=('e84c66e776f7c22c961817387f618c81'
+ '5b3fc74b8b7a6b99975312d0411960ed')
+
+prepare() {
+ mkdir build
+
+ # Disable building tests
+ sed -i '/tests/ d' ${pkgname}-${pkgver}/CMakeLists.txt
+}
+
+build() {
+ cd build
+ cmake ../${pkgname}-${pkgver} \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_BUILD_TYPE=Release
+ make
+}
+
+package() {
+ cd build
+ make DESTDIR="${pkgdir}" install
+
+ # Install config file for apps that need "Activate" action
+ install -Dm644 "${srcdir}/sni-qt.conf" "${pkgdir}/etc/sni-qt.conf"
+}
Property changes on: sni-qt/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list