[arch-commits] Commit in (4 files)

Antonio Rojas arojas at archlinux.org
Sun Dec 21 14:56:52 UTC 2014


    Date: Sunday, December 21, 2014 @ 15:56:52
  Author: arojas
Revision: 124308

Sage notebook dependency

Added:
  python-webassets/
  python-webassets/.AURINFO
  python-webassets/trunk/
  python-webassets/trunk/PKGBUILD

----------------+
 .AURINFO       |   16 ++++++++++++++++
 trunk/PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)

Added: python-webassets/.AURINFO
===================================================================
--- python-webassets/.AURINFO	                        (rev 0)
+++ python-webassets/.AURINFO	2014-12-21 14:56:52 UTC (rev 124308)
@@ -0,0 +1,16 @@
+pkgbase = python2-webassets
+	pkgdesc = Media asset management for Python, with glue code for various web frameworks.
+	pkgver = 0.10.1
+	pkgrel = 1
+	url = http://github.com/miracle2k/webassets/
+	arch = any
+	license = BSD
+	depends = python2
+	depends = python2-django
+	optdepends = python2-pillow: support for image manipulation
+	optdepends = python2-nose: required to run tests
+	optdepends = python2-mock: required to run tests
+	source = http://pypi.python.org/packages/source/w/webassets/webassets-0.10.1.tar.gz
+
+pkgname = python2-webassets
+

Added: python-webassets/trunk/PKGBUILD
===================================================================
--- python-webassets/trunk/PKGBUILD	                        (rev 0)
+++ python-webassets/trunk/PKGBUILD	2014-12-21 14:56:52 UTC (rev 124308)
@@ -0,0 +1,46 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+
+pkgbase=python-webassets
+pkgname=('python2-webassets' 'python-webassets')
+_pipname=webassets
+pkgver=0.10.1
+pkgrel=1
+pkgdesc="Media asset management for Python, with glue code for various web frameworks."
+arch=(any)
+url="http://github.com/miracle2k/webassets/"
+license=('BSD')
+makedepends=('python2-django' 'python-django' 'python2-setuptools' 'python-setuptools')
+source=("http://pypi.python.org/packages/source/w/${_pipname}/${_pipname}-${pkgver}.tar.gz")
+md5sums=('8007980e0ef38c9a42f577b2b2362e76')
+
+prepare() {
+    cp -R $_pipname-$pkgver python2-$_pipname-$pkgver
+}
+
+package_python2-webassets() {
+depends=('python2-django')
+optdepends=('python2-pillow: support for image manipulation'
+            'python2-nose: required to run tests'
+            'python2-mock: required to run tests')
+
+    cd python2-$_pipname-$pkgver
+    python2 setup.py install --root="$pkgdir/" --optimize=1
+
+    sed -e 's|#!/usr/bin/env python|#!/usr/bin/env python2|' -i "$pkgdir"/usr/lib/python2.7/site-packages/webassets/filter/rjsmin/rjsmin.py
+
+    mkdir -p "$pkgdir"/usr/share/licenses/$pkgname
+    install -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname
+}
+
+package_python-webassets() {
+depends=('python-django')
+optdepends=('python-pillow: support for image manipulation'
+            'python-nose: required to run tests'
+            'python-mock: required to run tests')
+
+    cd $_pipname-$pkgver 
+    python setup.py install --root="$pkgdir/" --optimize=1
+
+    mkdir -p "$pkgdir"/usr/share/licenses/$pkgname
+    install -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname
+}


Property changes on: python-webassets/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property



More information about the arch-commits mailing list