[arch-commits] Commit in lib32-libpulse/repos (2 files)

Jan Steffens heftig at nymeria.archlinux.org
Wed Feb 12 10:04:29 UTC 2014


    Date: Wednesday, February 12, 2014 @ 11:04:28
  Author: heftig
Revision: 105628

archrelease: copy trunk to multilib-testing-x86_64

Added:
  lib32-libpulse/repos/multilib-testing-x86_64/
  lib32-libpulse/repos/multilib-testing-x86_64/PKGBUILD
    (from rev 105627, lib32-libpulse/trunk/PKGBUILD)

----------+
 PKGBUILD |   64 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)

Copied: lib32-libpulse/repos/multilib-testing-x86_64/PKGBUILD (from rev 105627, lib32-libpulse/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-testing-x86_64/PKGBUILD	2014-02-12 10:04:28 UTC (rev 105628)
@@ -0,0 +1,64 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+# Contributor: Corrado Primier <bardo at aur.archlinux.org>
+# Contributor: William Rea <sillywilly at gmail.com>
+
+_pkgbasename=libpulse
+pkgname=lib32-$_pkgbasename
+pkgdesc="A featureful, general-purpose sound server (32-bit client libraries)"
+pkgver=4.99.3
+pkgrel=1
+arch=(x86_64)
+url="http://www.freedesktop.org/wiki/Software/PulseAudio"
+license=(LGPL)
+depends=(lib32-libdbus lib32-json-c lib32-systemd
+         lib32-libasyncns lib32-libcap lib32-libxtst lib32-libsm lib32-libsndfile
+         $_pkgbasename)
+makedepends=(gcc-multilib libtool-multilib intltool lib32-glib2 lib32-speex lib32-gtk2 git)
+optdepends=('lib32-alsa-plugins: ALSA support')
+provides=("lib32-pulseaudio=$pkgver")
+conflicts=(lib32-pulseaudio)
+replaces=(lib32-pulseaudio)
+options=(!emptydirs !libtool)
+#source=("http://freedesktop.org/software/pulseaudio/releases/pulseaudio-$pkgver.tar.xz")
+source=(pulseaudio-$pkgver::git://anongit.freedesktop.org/pulseaudio/pulseaudio#commit=6021ce3)
+sha256sums=('SKIP')
+
+_libs="libpulse.la libpulse-simple.la libpulse-mainloop-glib.la"
+_pkglibs="libpulsecommon-${pkgver%.*}.la libpulsedsp.la"
+
+prepare() {
+  cd pulseaudio-$pkgver
+}
+
+build() {
+  cd pulseaudio-$pkgver
+
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  ./autogen.sh --prefix=/usr \
+    --sysconfdir=/etc \
+    --libdir=/usr/lib32 \
+    --libexecdir=/usr/lib32 \
+    --localstatedir=/var \
+    --disable-tcpwrap \
+    --disable-bluez4 \
+    --disable-rpath \
+    --disable-default-build-tests
+
+  # fight unused direct deps
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make -C src $_libs $_pkglibs
+}
+
+package() {
+  cd pulseaudio-$pkgver
+  make -j1 -C src DESTDIR="$pkgdir" \
+    lib_LTLIBRARIES="$_libs" pkglib_LTLIBRARIES="$_pkglibs" \
+    install-libLTLIBRARIES install-pkglibLTLIBRARIES
+  make -j1 DESTDIR="$pkgdir" install-pkgconfigDATA
+}




More information about the arch-commits mailing list