[arch-commits] Commit in (5 files)
Martin Wimpress
flexiondotorg at nymeria.archlinux.org
Thu Jan 16 16:36:07 UTC 2014
Date: Thursday, January 16, 2014 @ 17:36:06
Author: flexiondotorg
Revision: 104196
Added mate-media
Added:
mate-media/
mate-media/repos/
mate-media/trunk/
mate-media/trunk/PKGBUILD
mate-media/trunk/mate-media-gstreamer.install
------------------------------+
PKGBUILD | 75 +++++++++++++++++++++++++++++++++++++++++
mate-media-gstreamer.install | 12 ++++++
2 files changed, 87 insertions(+)
Added: mate-media/trunk/PKGBUILD
===================================================================
--- mate-media/trunk/PKGBUILD (rev 0)
+++ mate-media/trunk/PKGBUILD 2014-01-16 16:36:06 UTC (rev 104196)
@@ -0,0 +1,75 @@
+# $Id$
+# Maintainer : Martin Wimpress <code at flexion.org>
+
+pkgbase=mate-media
+pkgname=("${pkgbase}-pulseaudio" "${pkgbase}-gstreamer")
+pkgver=1.6.1
+pkgrel=1
+url="http://mate-desktop.org"
+arch=('i686' 'x86_64')
+license=('GPL')
+depends=('gstreamer0.10-base-plugins' 'gtk2' 'libcanberra-pulse' 'libunique'
+ 'mate-desktop' 'mate-window-manager' 'pulseaudio')
+makedepends=('mate-common' 'mate-doc-utils' 'mate-panel'
+ 'mate-settings-daemon-gstreamer' 'perl-xml-parser')
+options=('!emptydirs')
+source=("http://pub.mate-desktop.org/releases/1.6/${pkgbase}-${pkgver}.tar.xz")
+sha1sums=('39acbf670a384325b5f68487e62bb1bdddb7d68f')
+
+build() {
+ cd "${srcdir}"
+ cp -a ${pkgbase}-${pkgver}{,-gstreamer}
+
+ # build for pulseaudio
+ cd "${srcdir}/${pkgbase}-${pkgver}"
+ ./autogen.sh \
+ --prefix=/usr \
+ --sysconfdir=/etc \
+ --libexecdir=/usr/lib/${pkgbase} \
+ --localstatedir=/var \
+ --enable-pulseaudio \
+ --disable-gstmix \
+ --disable-gst-mixer-applet \
+ --disable-static \
+ --disable-scrollkeeper
+ make
+
+ # build for gstreamer
+ cd "${srcdir}/${pkgbase}-${pkgver}-gstreamer"
+ ./autogen.sh \
+ --prefix=/usr \
+ --sysconfdir=/etc \
+ --libexecdir=/usr/lib/${pkgbase} \
+ --localstatedir=/var \
+ --enable-gstmix \
+ --enable-gst-mixer-applet \
+ --enable-deprecated \
+ --disable-pulseaudio \
+ --disable-static \
+ --disable-scrollkeeper
+ make
+}
+
+package_mate-media-pulseaudio() {
+ groups=('mate-extra')
+ pkgdesc="MATE Media Tools (pulseaudio)"
+ depends=('libcanberra-pulse' 'libunique' 'mate-desktop' 'mate-window-manager'
+ 'pulseaudio')
+ conflicts=("${pkgbase}-gstreamer" 'mate-settings-daemon-gstreamer')
+ provides=("${pkgbase}")
+ replaces=("${pkgbase}")
+ cd "${srcdir}/${pkgbase}-${pkgver}"
+ make DESTDIR="${pkgdir}" install
+}
+
+package_mate-media-gstreamer() {
+ pkgdesc="MATE Media Tools (GStreamer)"
+ depends=('gstreamer0.10-base-plugins' 'gtk2' 'libcanberra' 'mate-desktop'
+ 'mate-window-manager')
+ optdepends=('mate-panel: Volume control for the panel')
+ conflicts=("${pkgbase}-pulseaudio" 'mate-settings-daemon-pulseaudio')
+ provides=("${pkgbase}")
+ install=${pkgbase}-gstreamer.install
+ cd "${srcdir}/${pkgbase}-${pkgver}-gstreamer"
+ make DESTDIR="${pkgdir}" install
+}
Property changes on: mate-media/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: mate-media/trunk/mate-media-gstreamer.install
===================================================================
--- mate-media/trunk/mate-media-gstreamer.install (rev 0)
+++ mate-media/trunk/mate-media-gstreamer.install 2014-01-16 16:36:06 UTC (rev 104196)
@@ -0,0 +1,12 @@
+post_install() {
+ glib-compile-schemas /usr/share/glib-2.0/schemas/
+ gtk-update-icon-cache -q -t -f /usr/share/icons/mate
+}
+
+post_upgrade() {
+ post_install
+}
+
+post_remove() {
+ post_install
+}
More information about the arch-commits
mailing list