[arch-commits] Commit in (5 files)
Martin Wimpress
flexiondotorg at nymeria.archlinux.org
Thu Jan 16 17:09:40 UTC 2014
Date: Thursday, January 16, 2014 @ 18:09:40
Author: flexiondotorg
Revision: 104213
Added mate-power-manager
Added:
mate-power-manager/
mate-power-manager/repos/
mate-power-manager/trunk/
mate-power-manager/trunk/PKGBUILD
mate-power-manager/trunk/mate-power-manager.install
----------------------------+
PKGBUILD | 48 +++++++++++++++++++++++++++++++++++++++++++
mate-power-manager.install | 12 ++++++++++
2 files changed, 60 insertions(+)
Added: mate-power-manager/trunk/PKGBUILD
===================================================================
--- mate-power-manager/trunk/PKGBUILD (rev 0)
+++ mate-power-manager/trunk/PKGBUILD 2014-01-16 17:09:40 UTC (rev 104213)
@@ -0,0 +1,48 @@
+# $Id$
+# Maintainer : Martin Wimpress <code at flexion.org>
+# Contributor: Giovanni Ricciardi <kar98k.sniper at gmail.com>
+# Contributor: Xpander <xpander0 at gmail.com>
+# Contributor: hekel <hekel at archlinux.info>
+
+pkgname=mate-power-manager
+pkgver=1.6.3
+pkgrel=3
+pkgdesc="Session daemon that makes it easy to manage your laptop or desktop system for Mate Desktop"
+url="http://mate-desktop.org"
+arch=('i686' 'x86_64')
+license=('GPL')
+depends=('dbus-glib' 'dconf' 'libcanberra' 'libmatekeyring' 'libnotify'
+ 'libunique' 'upower')
+makedepends=('docbook2x' 'docbook-xml' 'mate-common' 'mate-doc-utils'
+ 'mate-panel' 'perl-xml-parser' 'xmlto')
+optdepends=('mate-panel: Set brightness and inhibit power management from the panel')
+options=('!emptydirs')
+groups=('mate-extra')
+source=("http://pub.mate-desktop.org/releases/1.6/${pkgname}-${pkgver}.tar.xz")
+sha1sums=('a949e34494cb70bcb2fa349dcc35847f022be187')
+install=${pkgname}.install
+
+prepare() {
+ cd "${srcdir}/${pkgname}-${pkgver}"
+ #Work around a problem where the .sgml fail to parse.
+ sed -e 's:@HAVE_DOCBOOK2MAN_TRUE at .*::' -i man/Makefile.in
+}
+
+build() {
+ cd "${srcdir}/${pkgname}-${pkgver}"
+ ./configure \
+ --prefix=/usr \
+ --libexecdir=/usr/lib/${pkgname} \
+ --sysconfdir=/etc \
+ --localstatedir=/var \
+ --sbindir=/usr/bin \
+ --enable-applets \
+ --enable-unique \
+ --disable-scrollkeeper
+ make
+}
+
+package() {
+ cd "${srcdir}/${pkgname}-${pkgver}"
+ make DESTDIR="${pkgdir}" install
+}
Property changes on: mate-power-manager/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: mate-power-manager/trunk/mate-power-manager.install
===================================================================
--- mate-power-manager/trunk/mate-power-manager.install (rev 0)
+++ mate-power-manager/trunk/mate-power-manager.install 2014-01-16 17:09:40 UTC (rev 104213)
@@ -0,0 +1,12 @@
+post_install() {
+ glib-compile-schemas /usr/share/glib-2.0/schemas/
+ gtk-update-icon-cache -q -t -f /usr/share/icons/hicolor
+}
+
+post_upgrade() {
+ post_install
+}
+
+post_remove() {
+ post_install
+}
More information about the arch-commits
mailing list