[arch-commits] Commit in (5 files)
Martin Wimpress
flexiondotorg at nymeria.archlinux.org
Thu Jan 16 17:34:27 UTC 2014
Date: Thursday, January 16, 2014 @ 18:34:26
Author: flexiondotorg
Revision: 104223
Added mate-document-viewer
Added:
mate-document-viewer/
mate-document-viewer/repos/
mate-document-viewer/trunk/
mate-document-viewer/trunk/PKGBUILD
mate-document-viewer/trunk/mate-document-viewer.install
------------------------------+
PKGBUILD | 50 +++++++++++++++++++++++++++++++++++++++++
mate-document-viewer.install | 13 ++++++++++
2 files changed, 63 insertions(+)
Added: mate-document-viewer/trunk/PKGBUILD
===================================================================
--- mate-document-viewer/trunk/PKGBUILD (rev 0)
+++ mate-document-viewer/trunk/PKGBUILD 2014-01-16 17:34:26 UTC (rev 104223)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer : Martin Wimpress <code at flexion.org>
+# Contributor: Giovanni "Talorno" Ricciardi <kar98k.sniper at gmail.com>
+# Contributor: Xpander <xpander0 at gmail.com>
+
+pkgname=mate-document-viewer
+pkgver=1.6.1
+pkgrel=5
+pkgdesc="Simply a document viewer"
+url="http://mate-desktop.org"
+arch=('i686' 'x86_64')
+license=('GPL')
+depends=('dconf' 'dbus' 'desktop-file-utils' 'gtk2' 'libmatekeyring' 'libsm'
+ 'libspectre' 'mate-icon-theme' 'poppler-glib' 'zlib')
+makedepends=('djvulibre' 'gobject-introspection' 'libgxps' 'mate-common'
+ 'mate-doc-utils' 'mate-file-manager' 'perl-xml-parser' 'texlive-bin')
+optdepends=('djvulibre: DjVu support'
+ 'libgxps: XPS support'
+ 'mate-file-manager: Document Properties extension'
+ 'p7zip: cbz and cb7 compressed comic books'
+ 'texlive-bin: DVI support'
+ 'unrar: cbr compressed comic books')
+options=('!emptydirs')
+groups=('mate-extra')
+source=("http://pub.mate-desktop.org/releases/1.6/${pkgname}-${pkgver}.tar.xz")
+sha1sums=('5b3d1643b7945d56214ec13dc38cb641dfb688e1')
+install=${pkgname}.install
+
+build() {
+ cd "${srcdir}/${pkgname}-${pkgver}"
+ ./autogen.sh \
+ --prefix=/usr \
+ --libexecdir=/usr/lib/${pkgname} \
+ --enable-gtk-doc \
+ --enable-djvu \
+ --enable-dvi \
+ --enable-t1lib \
+ --enable-pixbuf \
+ --enable-comics \
+ --enable-introspection \
+ --disable-static \
+ --disable-scrollkeeper
+ make
+}
+
+package() {
+ cd "${srcdir}/${pkgname}-${pkgver}"
+ make DESTDIR="${pkgdir}" install
+ ln -s atril "${pkgdir}/usr/bin/mate-document-viewer"
+}
Property changes on: mate-document-viewer/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: mate-document-viewer/trunk/mate-document-viewer.install
===================================================================
--- mate-document-viewer/trunk/mate-document-viewer.install (rev 0)
+++ mate-document-viewer/trunk/mate-document-viewer.install 2014-01-16 17:34:26 UTC (rev 104223)
@@ -0,0 +1,13 @@
+post_install() {
+ glib-compile-schemas /usr/share/glib-2.0/schemas/
+ gtk-update-icon-cache -q -t -f /usr/share/icons/hicolor
+ update-desktop-database -q
+}
+
+post_upgrade() {
+ post_install
+}
+
+post_remove() {
+ post_install
+}
More information about the arch-commits
mailing list