[arch-commits] Commit in meld/repos (3 files)

[Jan Steffens]

    Date: Saturday, July 12, 2014 @ 20:00:06
  Author: heftig
Revision: 216842

archrelease: copy trunk to testing-any

Added:
  meld/repos/testing-any/
  meld/repos/testing-any/PKGBUILD
    (from rev 216841, meld/trunk/PKGBUILD)
  meld/repos/testing-any/meld.install
    (from rev 216841, meld/trunk/meld.install)

--------------+
 PKGBUILD     |   35 +++++++++++++++++++++++++++++++++++
 meld.install |   14 ++++++++++++++
 2 files changed, 49 insertions(+)

Copied: meld/repos/testing-any/PKGBUILD (from rev 216841, meld/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD	                        (rev 0)
+++ testing-any/PKGBUILD	2014-07-12 18:00:06 UTC (rev 216842)
@@ -0,0 +1,35 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Gaetan Bisson <bisson at archlinux.org>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+# Contributor: Douglas Soares de Andrade <douglas at archlinux.org>
+
+pkgname=meld
+pkgver=3.11.2
+pkgrel=1
+pkgdesc='Visual diff and merge tool'
+url='http://meldmerge.org/'
+license=(GPL)
+arch=(any)
+makedepends=(intltool itstool)
+install=meld.install
+depends=(python2-gobject gtk3 hicolor-icon-theme desktop-file-utils)
+optdepends=('gtksourceview3: syntax highlighting'
+            'python2-dbus: open a new tab in an already running instance')
+source=("http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver%.*}/$pkgname-${pkgver}.tar.xz")
+sha1sums=('9d2dfe0579241ff8f4e9681945fb9cd229947edc')
+
+# Meld does not support Python 3. The build succeeds, but
+# the main executable checks the version and errors out.
+
+build() {
+  cd $pkgname-$pkgver
+  python2 setup.py build
+}
+
+package() {
+  cd $pkgname-$pkgver
+  # using --skip-build breaks install
+  python2 setup.py --no-update-icon-cache --no-compile-schemas \
+    install --prefix=/usr --root="$pkgdir" --optimize=1
+}

Copied: meld/repos/testing-any/meld.install (from rev 216841, meld/trunk/meld.install)
===================================================================
--- testing-any/meld.install	                        (rev 0)
+++ testing-any/meld.install	2014-07-12 18:00:06 UTC (rev 216842)
@@ -0,0 +1,14 @@
+post_install() {
+  gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
+  glib-compile-schemas usr/share/glib-2.0/schemas
+  update-desktop-database -q
+  update-mime-database usr/share/mime &> /dev/null
+}
+
+post_upgrade() {
+  post_install
+}
+
+post_remove() {
+  post_install
+}