[arch-commits] Commit in (4 files)

Felix Yan fyan at archlinux.org
Wed Jul 16 02:30:04 UTC 2014


    Date: Wednesday, July 16, 2014 @ 04:30:04
  Author: fyan
Revision: 115749

addpkg: python-certifi 14.05.14-1 as new dependency of tornado 4.0.0

Added:
  python-certifi/
  python-certifi/repos/
  python-certifi/trunk/
  python-certifi/trunk/PKGBUILD

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Added: python-certifi/trunk/PKGBUILD
===================================================================
--- python-certifi/trunk/PKGBUILD	                        (rev 0)
+++ python-certifi/trunk/PKGBUILD	2014-07-16 02:30:04 UTC (rev 115749)
@@ -0,0 +1,48 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at gmail.com>
+# Contributor: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+# Contributor: William J Bowman <bluephoenix47 at gmail.com>
+
+pkgbase=python-certifi
+pkgname=('python-certifi' 'python2-certifi')
+_libname=${pkgbase/python-/}
+pkgver=14.05.14
+pkgrel=1
+pkgdesc="Mozilla's SSL Certs"
+arch=(any)
+url="http://pypi.python.org/pypi/certifi"
+license=('GPL')
+makedepends=('python-setuptools' 'python2-setuptools')
+source=("http://pypi.python.org/packages/source/${_libname:0:1}/$_libname/$_libname-$pkgver.tar.gz")
+sha512sums=('5edba0cc432c27212e31085fb3c2f2ded6fa177d716116111517c25b980d9fc206a9a6d47e2c001762e951ff50203b269d0eb245a039df20188b1136f3b700b2')
+
+prepare() {
+  cp -a $_libname-$pkgver{,-py2}
+
+  cd $_libname-$pkgver-py2
+  sed -i '1s|python$|python2|' certifi/core.py
+}
+
+build() {
+  cd "$srcdir/$_libname-$pkgver"
+  python setup.py build
+
+  cd "$srcdir/$_libname-$pkgver-py2"
+  python2 setup.py build
+}
+
+package_python-certifi() {
+  depends=('python')
+
+  cd "$srcdir/$_libname-$pkgver"
+  python setup.py install --skip-build -O1 --root="$pkgdir"
+  install -m0644 -D "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-certifi() {
+  depends=('python2')
+
+  cd "$srcdir/$_libname-$pkgver-py2"
+  python2 setup.py install --skip-build -O1 --root="$pkgdir"
+  install -m0644 -D "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}


Property changes on: python-certifi/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property



More information about the arch-commits mailing list