[arch-commits] Commit in python-mako/repos (testing-any testing-any/PKGBUILD)

[Felix Yan]

    Date: Monday, June 9, 2014 @ 02:33:52
  Author: fyan
Revision: 214398

archrelease: copy trunk to testing-any

Added:
  python-mako/repos/testing-any/
  python-mako/repos/testing-any/PKGBUILD
    (from rev 214397, python-mako/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: python-mako/repos/testing-any/PKGBUILD (from rev 214397, python-mako/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD	                        (rev 0)
+++ testing-any/PKGBUILD	2014-06-09 00:33:52 UTC (rev 214398)
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at gmail.com>
+
+pkgname=('python-mako' 'python2-mako')
+pkgver=1.0.0
+pkgrel=1
+pkgdesc="Hyperfast and lightweight templating for the Python2 platform"
+arch=('any')
+url="http://www.makotemplates.org/"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-markupsafe' 'python2-markupsafe'
+             'python-beaker' 'python2-beaker')
+checkdepends=('python-nose' 'python2-nose' 'python-mock' 'python2-mock')
+source=(https://pypi.python.org/packages/source/M/Mako/Mako-$pkgver.tar.gz{,.asc})
+sha1sums=('580b3a8043833e3c3340d4b661a33f6ccc6a35d5'
+          'SKIP')
+
+prepare() {
+    cp -r Mako-$pkgver python2-Mako-$pkgver
+}
+
+build() {
+    cd Mako-$pkgver
+    python3 setup.py build
+
+    cd ../python2-Mako-$pkgver
+    python2 setup.py build
+}
+
+check() {
+    cd Mako-$pkgver
+    python3 setup.py test
+
+    cd ../python2-Mako-$pkgver
+    python2 setup.py test
+}
+
+package_python-mako() {
+    depends=('python-markupsafe' 'python-beaker')
+
+    cd Mako-$pkgver
+    python3 setup.py install --root="$pkgdir" --optimize=1
+    install -D LICENSE "$pkgdir/usr/share/licenses/python-mako/COPYING"
+}
+
+package_python2-mako() {
+    depends=('python2-markupsafe' 'python2-beaker')
+
+    cd python2-Mako-$pkgver
+    python2 setup.py install --root="$pkgdir" --optimize=1
+    install -D LICENSE "$pkgdir/usr/share/licenses/python2-mako/COPYING"
+
+    mv "$pkgdir/usr/bin/mako-render" "$pkgdir/usr/bin/mako-render2"
+}