[arch-commits] Commit in (4 files)
Andrzej Giniewicz
aginiewicz at nymeria.archlinux.org
Mon Jun 9 10:50:56 UTC 2014
Date: Monday, June 9, 2014 @ 12:50:55
Author: aginiewicz
Revision: 112878
Finally moving python-pandas to community
Added:
python-pandas/
python-pandas/repos/
python-pandas/trunk/
python-pandas/trunk/PKGBUILD
----------+
PKGBUILD | 78 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 78 insertions(+)
Added: python-pandas/trunk/PKGBUILD
===================================================================
--- python-pandas/trunk/PKGBUILD (rev 0)
+++ python-pandas/trunk/PKGBUILD 2014-06-09 10:50:55 UTC (rev 112878)
@@ -0,0 +1,78 @@
+# $Id$
+# Maintainer: Andrzej Giniewicz <gginiu at gmail.com>
+# Contributor: Keith Hughitt <khughitt at umd.edu>
+
+pkgbase=python-pandas
+pkgname=('python2-pandas' 'python-pandas')
+pkgver=0.14.0
+pkgrel=0
+pkgdesc="Cross-section and time series data analysis toolkit"
+arch=('i686' 'x86_64')
+url="http://pandas.pydata.org/"
+license=('BSD')
+makedepends=('python-setuptools' 'python-dateutil' 'python-numpy' 'python-pytz'
+ 'python2-setuptools' 'python2-dateutil' 'python2-numpy' 'python2-pytz')
+source=("https://pypi.python.org/packages/source/p/pandas/pandas-${pkgver}.tar.gz")
+md5sums=('b775987c0ceebcc8d5ace4a1241c967a')
+
+build() {
+ cd "$srcdir"
+ cp -a pandas-${pkgver} pandas-py2-${pkgver}
+
+ msg "Building Python2"
+ cd "$srcdir"/pandas-py2-${pkgver}
+ python2 setup.py build_ext --inplace
+ python2 setup.py build
+
+ msg "Building Python3"
+ cd "$srcdir"/pandas-${pkgver}
+ python setup.py build_ext --inplace
+ python setup.py build
+}
+
+package_python2-pandas() {
+ depends=('python2-numpy' 'python2-dateutil' 'python2-pytz')
+ optdepends=('python2-numexpr: needed for accelerating certain numerical operations (recommended)'
+ 'python2-bottleneck: needed for accelerating certain types of nan evaluations (recommended)'
+ 'python2-scipy: needed for miscellaneous statistical functions'
+ 'python2-pytables: needed for HDF5-based storage'
+ 'python2-sqlalchemy: needed for SQL database support'
+ 'python2-matplotlib: needed for plotting'
+ 'python2-openpyxl1: needed for XLSX input/output'
+ 'python2-xlrd: needed for XLS input'
+ 'python2-xlwt: needed for XLS output'
+ 'python2-boto: needed for access Amazon S3'
+ 'python2-beautifulsoup4: needed for read_html function'
+ 'python2-lxml: needed for read_html function'
+ 'python2-html5lib: needed for read_hmlt function')
+
+ cd "$srcdir"/pandas-py2-${pkgver}
+
+ python2 setup.py install --skip-build --root="$pkgdir" --optimize=1
+
+ sed -i -e "s|#![ ]*/usr/bin/env python$|#!/usr/bin/env python2|" $(find "${pkgdir}" -name '*.py')
+
+ install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python-pandas() {
+ depends=('python-numpy' 'python-dateutil' 'python-pytz')
+ optdepends=('python-numexpr: needed for accelerating certain numerical operations (recommended)'
+ 'python-bottleneck: needed for accelerating certain types of nan evaluations (recommended)'
+ 'python-scipy: needed for miscellaneous statistical functions'
+ 'python-pytables: needed for HDF5-based storage'
+ 'python-sqlalchemy: needed for SQL database support'
+ 'python-matplotlib: needed for plotting'
+ 'python-openpyxl1: needed for XLSX input/output'
+ 'python-xlrd: needed for XLS input'
+ 'python-beautifulsoup4: needed for read_html function'
+ 'python-lxml: needed for read_html function'
+ 'python-html5lib: needed for read_hmlt function')
+
+ cd "$srcdir"/pandas-${pkgver}
+
+ python setup.py install --skip-build --root="$pkgdir" --optimize=1
+
+ install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
Property changes on: python-pandas/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list