[arch-commits] Commit in (4 files)
Jelle van der Waa
jelle at nymeria.archlinux.org
Sun Jun 29 10:42:45 UTC 2014
Date: Sunday, June 29, 2014 @ 12:42:45
Author: jelle
Revision: 113741
python-pyside: initial commit
Added:
python-pyside/
python-pyside/repos/
python-pyside/trunk/
python-pyside/trunk/PKGBUILD
----------+
PKGBUILD | 87 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 87 insertions(+)
Added: python-pyside/trunk/PKGBUILD
===================================================================
--- python-pyside/trunk/PKGBUILD (rev 0)
+++ python-pyside/trunk/PKGBUILD 2014-06-29 10:42:45 UTC (rev 113741)
@@ -0,0 +1,87 @@
+# Maintainer: lilydjwg <lilydjwg at gmail.com>
+# Contributor: Matthias Maennich <arch at maennich.net>
+# Contributor: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+# Contributor: Jan-Erik Meyer-Luetgens <nyan at meyer-luetgens dot de>
+pkgbase=python-pyside
+pkgname=python-pyside
+true && pkgname=(python-pyside-common python2-pyside python-pyside)
+_pkgrealname=pyside
+pkgver=1.2.2
+pkgrel=2
+pkgdesc="Provides LGPL Qt bindings for Python and related tools for binding generation. Will build for both Python 2 and 3 versions."
+arch=('i686' 'x86_64')
+license=('LGPL')
+url="http://qt-project.org/wiki/PySide"
+_qtver=4.8
+makedepends=('cmake' 'automoc4' 'qtwebkit' 'python' 'python2')
+optdepends=('qtwebkit: for PySide.QtWebKit')
+source=("http://download.qt-project.org/official_releases/pyside/${_pkgrealname}-qt${_qtver}+$pkgver.tar.bz2")
+
+depends=('python' 'python2' "qt4>=${_qtver}" 'phonon' "shiboken>=$pkgver")
+conflicts=('pyside-python2' 'pyside-python3')
+replaces=('pyside-python2' 'pyside-python3')
+
+build(){
+ cd $srcdir/${_pkgrealname}-qt${_qtver}+$pkgver
+ mkdir -p build_py3 && cd build_py3
+ _pyverflags=$(python -c 'import sysconfig; print(sysconfig.get_config_var("SOABI"))')
+ cmake .. -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release -DBUILD_TESTS=OFF \
+ -DQT_PHONON_INCLUDE_DIR=/usr/include/qt4/phonon -DQT_QMAKE_EXECUTABLE=qmake-qt4 \
+ -DPYTHON_SUFFIX=.${_pyverflags}
+ make
+
+ cd $srcdir/${_pkgrealname}-qt${_qtver}+$pkgver
+ mkdir -p build_py2 && cd build_py2
+ cmake .. -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release -DBUILD_TESTS=OFF \
+ -DQT_PHONON_INCLUDE_DIR=/usr/include/qt4/phonon -DQT_QMAKE_EXECUTABLE=qmake-qt4
+ make
+}
+
+package_python-pyside-common(){
+ true && depends=("qt4>=${_qtver}" 'phonon' "shiboken>=$pkgver")
+ true && pkgdesc="Provides LGPL Qt bindings for Python and related tools for binding generation. Common Files."
+ true && conflicts=()
+ true && replaces=()
+ true && optdepends=()
+ # cmake will use Python 3 version by default
+ cd $srcdir/${_pkgrealname}-qt${_qtver}+$pkgver/build_py3
+ make DESTDIR=$pkgdir install
+
+ rm -rf "$pkgdir"/usr/lib/python* "$pkgdir"/usr/lib/libpyside.* \
+ "$pkgdir"/usr/lib/cmake/PySide-$pkgver/PySideConfig*python*.cmake \
+ "$pkgdir"/usr/lib/pkgconfig/pyside.pc
+}
+
+package_python-pyside(){
+ true && depends=('python' "qt4>=${_qtver}" 'phonon' "shiboken>=$pkgver" "python-pyside-common=$pkgver")
+ true && pkgdesc="Provides LGPL Qt bindings for Python and related tools for binding generation. Python 3 version."
+ true && conflicts=('pyside-python3')
+ true && replaces=('pyside-python3')
+
+ cd $srcdir/${_pkgrealname}-qt${_qtver}+$pkgver/build_py3
+ make DESTDIR=$pkgdir install
+ mv "$pkgdir"/usr/lib/pkgconfig/pyside.pc \
+ "$pkgdir"/usr/lib/pkgconfig/pyside-py3.pc
+ rm -rf "$pkgdir"/usr/include \
+ "$pkgdir"/usr/lib/cmake/PySide-$pkgver/PySideConfig.cmake \
+ "$pkgdir"/usr/lib/cmake/PySide-$pkgver/PySideConfigVersion.cmake \
+ "$pkgdir"/usr/share
+}
+
+package_python2-pyside(){
+ true && depends=('python' "qt4>=${_qtver}" 'phonon' "shiboken>=$pkgver" "python-pyside-common=$pkgver")
+ true && pkgdesc="Provides LGPL Qt bindings for Python and related tools for binding generation. Python 2 version."
+ true && conflicts=('pyside-python2')
+ true && replaces=('pyside-python2')
+
+ cd $srcdir/${_pkgrealname}-qt${_qtver}+$pkgver/build_py2
+ make DESTDIR=$pkgdir install
+ mv "$pkgdir"/usr/lib/pkgconfig/pyside.pc \
+ "$pkgdir"/usr/lib/pkgconfig/pyside-py2.pc
+ rm -rf "$pkgdir"/usr/include \
+ "$pkgdir"/usr/lib/cmake/PySide-$pkgver/PySideConfig.cmake \
+ "$pkgdir"/usr/lib/cmake/PySide-$pkgver/PySideConfigVersion.cmake \
+ "$pkgdir"/usr/share
+}
+
+md5sums=('1969c2ff90eefaa4b200d234059d2287')
Property changes on: python-pyside/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list