[arch-commits] Commit in (5 files)

[Martin Wimpress]

    Date: Wednesday, March 5, 2014 @ 21:15:23
  Author: flexiondotorg
Revision: 106528

Added caja

Added:
  caja/
  caja/repos/
  caja/trunk/
  caja/trunk/PKGBUILD
  caja/trunk/caja.install

--------------+
 PKGBUILD     |   41 +++++++++++++++++++++++++++++++++++++++++
 caja.install |   14 ++++++++++++++
 2 files changed, 55 insertions(+)

Added: caja/trunk/PKGBUILD
===================================================================
--- caja/trunk/PKGBUILD	                        (rev 0)
+++ caja/trunk/PKGBUILD	2014-03-05 20:15:23 UTC (rev 106528)
@@ -0,0 +1,41 @@
+# $Id$
+# Maintainer : Martin Wimpress <code at flexion.org>
+
+pkgname=caja
+pkgver=1.8.0
+pkgrel=1
+pkgdesc="The MATE shell and file manager"
+url="http://mate-desktop.org"
+arch=('i686' 'x86_64')
+license=('GPL')
+depends=('dbus' 'desktop-file-utils' 'exempi' 'gtk2' 'gvfs' 'libexif' 'libunique'
+         'libxt' 'mate-desktop' 'mate-icon-theme' 'startup-notification')
+makedepends=('gobject-introspection' 'mate-common' 'pangox-compat')
+optdepends=('gstreamer0.10-good-plugins: automatic media playback when mouseover'
+            'gvfs-smb: To connect to Samba/Windows shares')
+replaces=('mate-file-manager')
+provides=('mate-file-manager')
+conflicts=('mate-file-manager')
+options=('!emptydirs')
+groups=('mate')
+source=("http://pub.mate-desktop.org/releases/1.8/${pkgname}-${pkgver}.tar.xz")
+sha1sums=('3bfb52dceae4fa7b39eb26099b07326fa4197f3f')
+install=${pkgname}.install
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    ./configure \
+        --prefix=/usr \
+        --libexecdir=/usr/lib/${pkgname} \
+        --with-gtk=2.0 \
+        --enable-unique \
+        --enable-introspection \
+        --disable-static \
+        --disable-update-mimedb
+    make
+}
+
+package() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    make DESTDIR="${pkgdir}" install
+}


Property changes on: caja/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: caja/trunk/caja.install
===================================================================
--- caja/trunk/caja.install	                        (rev 0)
+++ caja/trunk/caja.install	2014-03-05 20:15:23 UTC (rev 106528)
@@ -0,0 +1,14 @@
+post_install() {
+    glib-compile-schemas /usr/share/glib-2.0/schemas/
+    update-mime-database /usr/share/mime/ > /dev/null
+    gtk-update-icon-cache -q -t -f /usr/share/icons/hicolor
+    update-desktop-database -q
+}
+
+post_upgrade() {
+    post_install
+}
+
+post_remove() {
+    post_install
+}