[arch-commits] Commit in (5 files)
Martin Wimpress
flexiondotorg at nymeria.archlinux.org
Wed Mar 5 20:16:36 UTC 2014
Date: Wednesday, March 5, 2014 @ 21:16:35
Author: flexiondotorg
Revision: 106535
Added pluma
Added:
pluma/
pluma/repos/
pluma/trunk/
pluma/trunk/PKGBUILD
pluma/trunk/pluma.install
---------------+
PKGBUILD | 44 ++++++++++++++++++++++++++++++++++++++++++++
pluma.install | 12 ++++++++++++
2 files changed, 56 insertions(+)
Added: pluma/trunk/PKGBUILD
===================================================================
--- pluma/trunk/PKGBUILD (rev 0)
+++ pluma/trunk/PKGBUILD 2014-03-05 20:16:35 UTC (rev 106535)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer : Martin Wimpress <code at flexion.org>
+
+pkgname=pluma
+pkgver=1.8.0
+pkgrel=1
+pkgdesc="A powerful text editor for MATE"
+url="http://mate-desktop.org"
+arch=('i686' 'x86_64')
+license=('GPL')
+depends=('caja' 'desktop-file-utils' 'enchant' 'gtk2' 'gtksourceview2'
+ 'iso-codes' 'libsm' 'mate-desktop' 'python2' 'python2-gobject2'
+ 'pygtksourceview2')
+makedepends=('mate-common' 'perl-xml-parser' 'yelp-tools')
+optdepends=('yelp: for reading MATE help documents')
+replaces=('mate-text-editor')
+provides=('mate-text-editor')
+conflicts=('mate-text-editor')
+options=('!emptydirs')
+groups=('mate-extra')
+source=("http://pub.mate-desktop.org/releases/1.8/${pkgname}-${pkgver}.tar.xz")
+sha1sums=('858e3edaee698b3f99189d3285061ab56b21828c')
+install=${pkgname}.install
+
+prepare() {
+ cd "${srcdir}/${pkgname}-${pkgver}"
+ sed -i 's/python/python2/' plugins/externaltools/data/switch-c.tool.in
+}
+
+build() {
+ cd "${srcdir}/${pkgname}-${pkgver}"
+ PYTHON=/usr/bin/python2 ./configure \
+ --prefix=/usr \
+ --libexecdir=/usr/lib/${pkgname} \
+ --with-gtk=2.0 \
+ --enable-gtk-doc \
+ --enable-python
+ make
+}
+
+package() {
+ cd "${srcdir}/${pkgname}-${pkgver}"
+ make DESTDIR="${pkgdir}" install
+}
Property changes on: pluma/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: pluma/trunk/pluma.install
===================================================================
--- pluma/trunk/pluma.install (rev 0)
+++ pluma/trunk/pluma.install 2014-03-05 20:16:35 UTC (rev 106535)
@@ -0,0 +1,12 @@
+post_install() {
+ glib-compile-schemas /usr/share/glib-2.0/schemas/
+ update-desktop-database -q
+}
+
+post_upgrade() {
+ post_install
+}
+
+post_remove() {
+ post_install
+}
More information about the arch-commits
mailing list