[arch-commits] Commit in catfish/repos/community-any (PKGBUILD catfish.install)

[Felix Yan]

    Date: Thursday, March 6, 2014 @ 16:22:19
  Author: fyan
Revision: 106683

archrelease: copy trunk to community-any

Added:
  catfish/repos/community-any/PKGBUILD
    (from rev 106682, catfish/trunk/PKGBUILD)
  catfish/repos/community-any/catfish.install
    (from rev 106682, catfish/trunk/catfish.install)

-----------------+
 PKGBUILD        |   44 ++++++++++++++++++++++++++++++++++++++++++++
 catfish.install |   11 +++++++++++
 2 files changed, 55 insertions(+)

Copied: catfish/repos/community-any/PKGBUILD (from rev 106682, catfish/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2014-03-06 15:22:19 UTC (rev 106683)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Jaroslav Lichtblau <dragonlord at aur.archlinux.org>
+# Contributor: Alexander Fehr <pizzapunk gmail com>
+
+pkgname=catfish
+pkgver=1.0.1
+pkgrel=1
+pkgdesc='Versatile file searching tool'
+arch=('any')
+url='https://launchpad.net/catfish-search'
+license=('GPL')
+install=$pkgname.install 
+depends=('gtk3' 'python2-gobject' 'python2-xdg' 'xdg-utils' 'python2-pexpect')
+makedepends=('intltool')
+optdepends=('zeitgeist: Zeitgeist integration'
+            'findutils: filename search'
+            'mlocate:    filename search'
+            'tracker:   fulltext search'
+            'strigi:    fulltext search'
+            'pinot:     fulltext search')
+source=(https://launchpad.net/catfish-search/${pkgver%.*}/$pkgver/+download/$pkgname-$pkgver.tar.bz2)
+md5sums=('54f67f33ab475a826a18d621c8861458')
+
+prepare() {
+  cd $pkgname-$pkgver
+  sed -i '1s/python/python2/' {bin,catfish,catfish_lib}/*.py build.py
+  sed -i 's|ln -sf $(PREFIX)/share|ln -sf ..|' Makefile.in.in
+}
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure --prefix=/usr \
+    --python=python2
+  make
+}
+
+package () {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+
+  install -d "$pkgdir"/usr/share/pixmaps
+  ln -s ../icons/hicolor/scalable/apps/$pkgname.svg \
+    "$pkgdir"/usr/share/pixmaps/$pkgname.svg
+}

Copied: catfish/repos/community-any/catfish.install (from rev 106682, catfish/trunk/catfish.install)
===================================================================
--- catfish.install	                        (rev 0)
+++ catfish.install	2014-03-06 15:22:19 UTC (rev 106683)
@@ -0,0 +1,11 @@
+post_install() {
+	xdg-icon-resource forceupdate
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}