[arch-commits] Commit in python-sympy/repos (2 files)
Felix Yan
fyan at nymeria.archlinux.org
Mon Mar 17 06:06:48 UTC 2014
Date: Monday, March 17, 2014 @ 07:06:48
Author: fyan
Revision: 107343
archrelease: copy trunk to community-staging-any
Added:
python-sympy/repos/community-staging-any/
python-sympy/repos/community-staging-any/PKGBUILD
(from rev 107342, python-sympy/trunk/PKGBUILD)
----------+
PKGBUILD | 77 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 77 insertions(+)
Copied: python-sympy/repos/community-staging-any/PKGBUILD (from rev 107342, python-sympy/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD (rev 0)
+++ community-staging-any/PKGBUILD 2014-03-17 06:06:48 UTC (rev 107343)
@@ -0,0 +1,77 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at gmail.com>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
+# Contributor: Peter Garceau <RockyChimp at gmail.com>
+
+pkgbase=python-sympy
+pkgname=('python2-sympy' 'python-sympy')
+pkgver=0.7.5
+pkgrel=2
+arch=('any')
+pkgdesc='Symbolic manipulation package (Computer Algebra System), written in pure Python'
+url='http://sympy.org/en/index.html'
+license=('BSD')
+makedepends=('python2' 'python' 'git')
+source=("git+https://github.com/sympy/sympy.git#tag=sympy-${pkgver}")
+
+prepare() {
+ cp -r sympy py3-sympy
+
+ sed -i -e 's|#!/usr/bin/env python|#!/usr/bin/env python2|' \
+ -e 's|#!/usr/bin/python|#!/usr/bin/python2|' \
+ sympy/sympy/mpmath/tests/{runtests.py,test_eigen.py,test_levin.py,test_eigen_symmetric.py} \
+ sympy/sympy/mpmath/matrices/{eigen.py,eigen_symmetric.py} \
+ sympy/sympy/utilities/tests/diagnose_imports.py
+ sed -i -e 's|#!/usr/bin/env python|#!/usr/bin/env python3|' \
+ -e 's|#!/usr/bin/python|#!/usr/bin/python3|' \
+ py3-sympy/sympy/mpmath/tests/{runtests.py,test_eigen.py,test_levin.py,test_eigen_symmetric.py} \
+ py3-sympy/sympy/mpmath/matrices/{eigen.py,eigen_symmetric.py} \
+ py3-sympy/sympy/utilities/tests/diagnose_imports.py
+}
+
+build() {
+ cd sympy
+ python2 setup.py build
+
+ cd ../py3-sympy
+ python3 setup.py build
+}
+
+#check() {
+# cd sympy
+# python2 setup.py test
+#
+# cd ../py3-sympy
+# python3 setup.py test
+#}
+
+package_python2-sympy() {
+ depends=('python2>=2.7')
+ optdepends=('python2-pyglet: plotting'
+ 'ipython2: user friendly interface for isympy')
+
+ cd sympy
+
+ python2 setup.py install --root "${pkgdir}" --optimize=1
+
+ install -D -m644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}
+
+package_python-sympy() {
+ depends=('python>=3.3')
+ optdepends=('ipython: user friendly interface for isympy')
+
+ cd py3-sympy
+
+ python3 setup.py install --root "${pkgdir}" --optimize=1
+
+ # rename files that exists in both 'python2-sympy' and 'python-sympy'
+ mv "${pkgdir}"/usr/bin/isympy{,-py3}
+ mv "${pkgdir}"/usr/share/man/man1/isympy{,-py3}.1
+
+ install -D -m644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}
+
+sha512sums=('SKIP')
More information about the arch-commits
mailing list