[arch-commits] Commit in python-pycparser/repos (staging-any staging-any/PKGBUILD)
Felix Yan
fyan at nymeria.archlinux.org
Mon Mar 17 06:15:24 UTC 2014
Date: Monday, March 17, 2014 @ 07:15:24
Author: fyan
Revision: 208023
archrelease: copy trunk to staging-any
Added:
python-pycparser/repos/staging-any/
python-pycparser/repos/staging-any/PKGBUILD
(from rev 208022, python-pycparser/trunk/PKGBUILD)
----------+
PKGBUILD | 53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 53 insertions(+)
Copied: python-pycparser/repos/staging-any/PKGBUILD (from rev 208022, python-pycparser/trunk/PKGBUILD)
===================================================================
--- staging-any/PKGBUILD (rev 0)
+++ staging-any/PKGBUILD 2014-03-17 06:15:24 UTC (rev 208023)
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at gmail.com>
+# Contributor: Justin Dray <justin at dray.be>
+# Contributor: Alexander Rødseth <rodseth at gmail.com>
+# Contributor: lang2 <wenzhi.liang at gmail.com>
+
+pkgbase=python-pycparser
+pkgname=(python-pycparser python2-pycparser)
+pkgver=2.10
+pkgrel=4
+pkgdesc='C parser and AST generator written in Python'
+url='https://github.com/eliben/pycparser'
+makedepends=('python-ply' 'python2-ply' 'git')
+arch=('any')
+license=('BSD')
+source=('https://github.com/eliben/pycparser/archive/release_v2.10.zip')
+sha256sums=('1217244f882c330782f4762a1fb37cef21a929ce0123ac388e7e367c35ddbae3')
+
+prepare() {
+ cp -r pycparser-release_v${pkgver}{,-py2}
+}
+
+build() {
+ cd pycparser-release_v${pkgver}
+ python setup.py build
+
+ cd pycparser
+ python _build_tables.py
+
+ cd "$srcdir/pycparser-release_v${pkgver}-py2"
+ python2 setup.py build
+
+ cd pycparser
+ python2 _build_tables.py
+}
+
+package_python-pycparser() {
+ depends=('python-ply')
+
+ cd pycparser-release_v${pkgver}
+
+ python setup.py install --root="$pkgdir" --optimize=1
+ install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-pycparser() {
+ depends=('python2-ply')
+
+ cd pycparser-release_v${pkgver}-py2
+
+ python2 setup.py install --root="$pkgdir" --optimize=1
+ install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
More information about the arch-commits
mailing list