[arch-commits] Commit in django/repos (staging-any staging-any/PKGBUILD)

[Dan McGee]

    Date: Tuesday, March 18, 2014 @ 01:01:14
  Author: dan
Revision: 208106

archrelease: copy trunk to staging-any

Added:
  django/repos/staging-any/
  django/repos/staging-any/PKGBUILD
    (from rev 208105, django/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: django/repos/staging-any/PKGBUILD (from rev 208105, django/trunk/PKGBUILD)
===================================================================
--- staging-any/PKGBUILD	                        (rev 0)
+++ staging-any/PKGBUILD	2014-03-18 00:01:14 UTC (rev 208106)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Dan McGee <dan at archlinux.org>
+# Contributor: Shahar Weiss <sweiss4 at gmx.net>
+
+pkgbase=django
+pkgname=('python-django' 'python2-django')
+pkgver=1.6.2
+pkgrel=2
+pkgdesc="A high-level Python Web framework that encourages rapid development and clean design"
+arch=('any')
+license=('BSD')
+url="http://www.djangoproject.com/"
+makedepends=('python2' 'python2-setuptools' 'python' 'python-setuptools')
+source=("https://www.djangoproject.com/m/releases/${pkgver:0:3}/Django-$pkgver.tar.gz")
+md5sums=('45d974c623b3bfbf9976f3d808fe1ee9')
+sha256sums=('d1b3f8460e936f47846e7c4f80af951eda82a41c253c3a51ff3389863ff1c03a')
+
+build() {
+  cd "$srcdir/Django-$pkgver"
+  python2 setup.py build
+}
+
+package_python-django() {
+  depends=('python')
+  optdepends=('python-psycopg2: for PostgreSQL backend')
+  cd "$srcdir/Django-$pkgver"
+  python setup.py install --root="$pkgdir" --optimize=1
+
+  mv "$pkgdir"/usr/bin/django-admin.py "$pkgdir"/usr/bin/django-admin3.py
+  install -Dm644 extras/django_bash_completion \
+    "$pkgdir"/usr/share/bash-completion/completions/django-admin3.py
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-django() {
+  depends=('python2')
+  optdepends=('mysql-python: for MySQL backend'
+              'python2-psycopg2: for PostgreSQL backend')
+  replaces=('django')
+  conflicts=('django')
+  cd "$srcdir/Django-$pkgver"
+  python2 setup.py install --root="$pkgdir" --optimize=1
+
+  ln -s django-admin.py "$pkgdir"/usr/bin/django-admin2.py
+  install -Dm644 extras/django_bash_completion \
+    "$pkgdir"/usr/share/bash-completion/completions/django-admin.py
+  ln -s django-admin.py \
+    "$pkgdir"/usr/share/bash-completion/completions/manage.py
+
+  find "$pkgdir"/usr/lib/python2.7/site-packages/django/ -name '*.py' | \
+    xargs sed -i "s|#!/usr/bin/env python$|#!/usr/bin/env python2|"
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}