[arch-commits] Commit in pygobject/repos (2 files)
Jan de Groot
jgc at nymeria.archlinux.org
Mon Mar 24 13:31:39 UTC 2014
Date: Monday, March 24, 2014 @ 14:31:39
Author: jgc
Revision: 208552
archrelease: copy trunk to gnome-unstable-x86_64
Added:
pygobject/repos/gnome-unstable-x86_64/
pygobject/repos/gnome-unstable-x86_64/PKGBUILD
(from rev 208551, pygobject/trunk/PKGBUILD)
----------+
PKGBUILD | 55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 55 insertions(+)
Copied: pygobject/repos/gnome-unstable-x86_64/PKGBUILD (from rev 208551, pygobject/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD 2014-03-24 13:31:39 UTC (rev 208552)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Ionut Biru <ibiru at archlinux.org>
+
+pkgbase=pygobject
+pkgname=(python-gobject python2-gobject pygobject-devel)
+pkgver=3.12.0
+pkgrel=1
+arch=(i686 x86_64)
+url="https://live.gnome.org/PyGObject"
+license=(LGPL)
+makedepends=(python python2 python-cairo python2-cairo gobject-introspection gnome-common)
+source=(http://ftp.gnome.org/pub/gnome/sources/$pkgbase/${pkgver:0:4}/$pkgbase-$pkgver.tar.xz)
+sha256sums=('0d4485311fcfb073dc37432e36ad1d45bcf9f8796a1e8ff20a6494e0297dbd1a')
+
+prepare() {
+ mkdir build-py2 build-py3 devel
+ cd ${pkgbase}-${pkgver}
+ sed -i '/Werror=format/d' configure # gcc 4.8
+}
+
+build() {
+ cd build-py2
+ ../${pkgbase}-${pkgver}/autogen.sh --prefix=/usr --with-python=/usr/bin/python2
+ make
+
+ cd ../build-py3
+ ../${pkgbase}-${pkgver}/configure --prefix=/usr
+ make
+}
+
+package_python-gobject() {
+ pkgdesc="Python 3 bindings for GObject"
+ depends=('gobject-introspection' 'python-cairo' "pygobject-devel=$pkgver")
+
+ cd build-py3
+ make DESTDIR="$pkgdir" install
+ rm -r "$pkgdir"/usr/{include,lib/pkgconfig}
+}
+
+package_python2-gobject() {
+ pkgdesc="Python 2 bindings for GObject"
+ depends=('gobject-introspection' 'python2-cairo' "pygobject-devel=$pkgver")
+
+ cd build-py2
+ make DESTDIR="$pkgdir" install
+ mv "$pkgdir"/usr/{include,lib/pkgconfig} "$srcdir/devel"
+}
+
+package_pygobject-devel() {
+ pkgdesc="Development files for the pygobject bindings"
+ cd "devel"
+ mkdir -p "$pkgdir"/usr/{include,lib}
+ mv include "$pkgdir/usr/"
+ mv pkgconfig "$pkgdir/usr/lib/"
+}
More information about the arch-commits
mailing list