[arch-commits] Commit in (4 files)

Felix Yan fyan at nymeria.archlinux.org
Tue Mar 25 05:24:53 UTC 2014


    Date: Tuesday, March 25, 2014 @ 06:24:53
  Author: fyan
Revision: 108227

addpkg: python-redis 2.9.1-3

Added:
  python-redis/
  python-redis/repos/
  python-redis/trunk/
  python-redis/trunk/PKGBUILD

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Added: python-redis/trunk/PKGBUILD
===================================================================
--- python-redis/trunk/PKGBUILD	                        (rev 0)
+++ python-redis/trunk/PKGBUILD	2014-03-25 05:24:53 UTC (rev 108227)
@@ -0,0 +1,47 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at gmail.com>
+# Contributor: Karol 'Kenji Takahashi' Woźniak <kenji.sx>
+# Contributor: Pierre Gueth <pierre.gueth at gmail.com>
+
+pkgbase=python-redis
+pkgname=('python-redis' 'python2-redis')
+_basename=redis
+pkgver=2.9.1
+pkgrel=3
+pkgdesc='The Python interface to the Redis key-value store'
+arch=('any')
+url="http://github.com/andymccurdy/redis-py"
+license=('MIT')
+makedepends=('python' 'python2')
+source=("https://pypi.python.org/packages/source/r/${_basename}/${_basename}-${pkgver}.tar.gz")
+md5sums=('1da8ff78be75d7acf5d4684e77fc3606')
+
+prepare() {
+  cp -r ${_basename}-${pkgver}{,-py2}
+}
+
+build() {
+  cd ${_basename}-${pkgver}
+  python setup.py build
+
+  cd ../${_basename}-${pkgver}-py2
+  python2 setup.py build
+}
+
+package_python-redis() {
+  depends=('python')
+
+  cd ${_basename}-${pkgver}
+  python setup.py install --root=${pkgdir}/ --optimize=1
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-redis() {
+  depends=('python2')
+
+  cd ${_basename}-${pkgver}-py2
+  python2 setup.py install --root=${pkgdir}/ --optimize=1
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim:set ts=2 sw=2 et:


Property changes on: python-redis/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property



More information about the arch-commits mailing list