[arch-commits] Commit in (7 files)

[Alexander Rødseth]

    Date: Thursday, May 15, 2014 @ 20:28:42
  Author: arodseth
Revision: 111258

Added Tesseract. A beautiful and modern FPS game.

Based on Cube and Sauerbraten.

Added:
  tesseract-game/
  tesseract-game/repos/
  tesseract-game/repos/community-i686/
  tesseract-game/repos/community-x86_64/
  tesseract-game/trunk/
  tesseract-game/trunk/PKGBUILD
  tesseract-game/trunk/tesseract.sh

--------------+
 PKGBUILD     |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 tesseract.sh |    6 ++++++
 2 files changed, 52 insertions(+)

Added: tesseract-game/trunk/PKGBUILD
===================================================================
--- tesseract-game/trunk/PKGBUILD	                        (rev 0)
+++ tesseract-game/trunk/PKGBUILD	2014-05-15 18:28:42 UTC (rev 111258)
@@ -0,0 +1,46 @@
+# $Id$
+# Maintainer: Alexander Rødseth <rodseth at gmail.com>
+# Contributor: portals <portals at riseup.net>
+# Contributor: novemberist
+# Contributor: PyroDevil
+# Contributor: giacomogiorgianni at gmail.com 
+
+pkgname=tesseract-game
+pkgver=1
+pkgrel=1
+pkgdesc='Smooth and modern FPS game with map editing, instagib, DM and CTF'
+url='http://tesseract.gg/'
+arch=('x86_64' 'i686')
+license=('ZLIB')
+depends=('libgl' 'sdl2' 'sdl2_image' 'sdl2_mixer' 'libpng' 'mesa' 'zlib')
+makedepends=('subversion' 'gendesk' 'imagemagick')
+source=('tesseract::svn://svn.tuxfamily.org/svnroot/tesseract/main#revision=1678'
+        'tesseract_large.png::http://upload.wikimedia.org/wikipedia/commons/5/50/Truncated_tesseract_stereographic_%28tC%29.png'
+        'tesseract.sh')
+md5sums=('SKIP'
+         '3f7098fad57081bb1af0ee4771e20ad3'
+         'ab00bafb80c1c7764cba8f51120d4a9a')
+
+prepare() {
+  gendesk -n -f --pkgname tesseract --pkgdesc "$pkgdesc"
+  convert -transparent white -resize 48x48 tesseract_large.png tesseract.png 2> /dev/null
+}
+
+build() {
+  make -C tesseract/src
+}
+
+package() {
+  cd tesseract
+  make -C src install
+  install -d "$pkgdir/usr/share/tesseract-game/"
+  cp -R media/ config/ "$pkgdir/usr/share/tesseract-game"
+  install -Dm755 bin_unix/native_client "$pkgdir/usr/bin/tesseract-client"
+  install -Dm755 bin_unix/native_server "$pkgdir/usr/bin/tesseract-server"
+  install -Dm755 tesseract.sh "$pkgdir/usr/bin/tesseract-game"
+  install -Dm644 ../tesseract.desktop "$pkgdir/usr/share/applications/tesseract.desktop"
+  install -Dm644 ../tesseract.png "$pkgdir/usr/share/pixmaps/tesseract.png"
+  install -Dm644 src/readme_tesseract.txt "$pkgdir/usr/share/licenses/tesseract-game/LICENSE"
+}
+
+# vim:set ts=2 sw=2 et:


Property changes on: tesseract-game/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: tesseract-game/trunk/tesseract.sh
===================================================================
--- tesseract-game/trunk/tesseract.sh	                        (rev 0)
+++ tesseract-game/trunk/tesseract.sh	2014-05-15 18:28:42 UTC (rev 111258)
@@ -0,0 +1,6 @@
+#!/bin/sh
+TESS_BIN=/usr/bin/
+TESS_DATA=/usr/share/tesseract-game/
+TESS_OPTIONS="-u$HOME/.tesseract"
+cd "$TESS_DATA"
+exec "$TESS_BIN/tesseract-client" "$TESS_OPTIONS" "$@"