[arch-commits] Commit in python-mysql-connector/repos (2 files)

Evgeniy Alekseev arcanis at nymeria.archlinux.org
Fri May 30 04:52:48 UTC 2014


    Date: Friday, May 30, 2014 @ 06:52:48
  Author: arcanis
Revision: 112213

archrelease: copy trunk to community-staging-any

Added:
  python-mysql-connector/repos/community-staging-any/
  python-mysql-connector/repos/community-staging-any/PKGBUILD
    (from rev 112212, python-mysql-connector/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: python-mysql-connector/repos/community-staging-any/PKGBUILD (from rev 112212, python-mysql-connector/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2014-05-30 04:52:48 UTC (rev 112213)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Evgeniy Alekseev <arcanis.arch at gmail dot com>
+# Contributor: Raphaël Doursenaud <rdoursenaud at free dot fr>
+
+pkgbase=python-mysql-connector
+pkgname=('python-mysql-connector' 'python2-mysql-connector')
+_pkgname=mysql-connector-python
+pkgver=1.2.2
+pkgrel=1
+pkgdesc="A standardized database driver for Python platforms and development"
+arch=('any')
+url="http://dev.mysql.com/downloads/connector/python/"
+license=('GPL')
+depends=('python' 'python2')
+source=("http://cdn.mysql.com/Downloads/Connector-Python/${_pkgname}-${pkgver}.tar.gz")
+md5sums=('15b0e95e6224ed7c9bfb685a9d54d356')
+
+prepare() {
+  cp -r "${_pkgname}-${pkgver}" "${_pkgname}-${pkgver}-py2"
+  # change python to python2
+  find "${_pkgname}-${pkgver}-py2" -name '*.py' -type f -exec \
+      sed -i 's|env python|env python2|' {} \;
+}
+
+build() {
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+  python setup.py build
+
+  cd "${srcdir}/${_pkgname}-${pkgver}-py2"
+  python2 setup.py build
+}
+
+package_python-mysql-connector() {
+  depends=('python')
+
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+  python setup.py install --root="${pkgdir}" --optimize=1
+}
+
+package_python2-mysql-connector() {
+  depends=('python2')
+
+  cd "${srcdir}/${_pkgname}-${pkgver}-py2"
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+}




More information about the arch-commits mailing list