[arch-commits] Commit in (libdwarf libdwarf/trunk libdwarf/trunk/PKGBUILD)

Massimiliano Torromeo mtorromeo at archlinux.org
Wed Nov 19 14:22:08 UTC 2014


    Date: Wednesday, November 19, 2014 @ 15:22:08
  Author: mtorromeo
Revision: 122750

Added libdwarf in [community] as a dependency for hhvm

Added:
  libdwarf/
  libdwarf/trunk/
  libdwarf/trunk/PKGBUILD

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Added: libdwarf/trunk/PKGBUILD
===================================================================
--- libdwarf/trunk/PKGBUILD	                        (rev 0)
+++ libdwarf/trunk/PKGBUILD	2014-11-19 14:22:08 UTC (rev 122750)
@@ -0,0 +1,41 @@
+# $Id$
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+# Contributor: Alain Kalker <a.c.kalker at gmail.com>
+# Contributor: Marti Raudsepp <marti at juffo.org>
+
+pkgname=libdwarf
+pkgver=20140805
+pkgrel=2
+pkgdesc="A library for handling DWARF Debugging Information Format"
+arch=(i686 x86_64)
+license=('GPL' 'LGPL')
+url="http://www.prevanders.net/dwarf.html"
+depends=('elfutils')
+options+=('staticlibs')
+source=(http://www.prevanders.net/libdwarf-$pkgver.tar.gz)
+sha256sums=('d48219a1c240d05cf68d55a6a1ed0d4592f4a2dd8df48f19d7686e1f38f8bdfc')
+
+build() {
+  cd "$srcdir"/dwarf-$pkgver
+  ./configure --prefix=/usr --enable-shared
+  make
+}
+
+package() {
+  cd "$srcdir"/dwarf-$pkgver/libdwarf
+
+  install -dm755 "$pkgdir"/usr/lib
+  install -m644 libdwarf.{a,so} "$pkgdir"/usr/lib/
+
+  install -dm755 "$pkgdir"/usr/include/libdwarf
+  install -m644 dwarf.h libdwarf.h "$pkgdir"/usr/include/libdwarf/
+
+  install -dm755 "$pkgdir"/usr/share/doc/$pkgname
+  install -m644 README NEWS *.pdf "$pkgdir"/usr/share/doc/$pkgname/
+
+  # dwarfdump
+  cd "$srcdir"/dwarf-$pkgver/dwarfdump2
+  install -Dm755 dwarfdump "$pkgdir"/usr/bin/dwarfdump
+  install -Dm644 dwarfdump.1 "$pkgdir"/usr/share/man/man1/dwarfdump.1
+  install -Dm644 dwarfdump.conf "$pkgdir"/usr/lib/dwarfdump.conf
+}


Property changes on: libdwarf/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property


More information about the arch-commits mailing list