[arch-commits] Commit in (4 files)
Andrzej Giniewicz
aginiewicz at archlinux.org
Mon Nov 24 20:10:37 UTC 2014
Date: Monday, November 24, 2014 @ 21:10:37
Author: aginiewicz
Revision: 123086
adding python-uritemplate as a new dependency of python2-google-api-python-client
Added:
python-uritemplate/
python-uritemplate/repos/
python-uritemplate/trunk/
python-uritemplate/trunk/PKGBUILD
----------+
PKGBUILD | 52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 52 insertions(+)
Added: python-uritemplate/trunk/PKGBUILD
===================================================================
--- python-uritemplate/trunk/PKGBUILD (rev 0)
+++ python-uritemplate/trunk/PKGBUILD 2014-11-24 20:10:37 UTC (rev 123086)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Andrzej Giniewicz <gginiu at gmail.com>
+
+pkgbase=python-uritemplate
+pkgname=('python2-uritemplate' 'python-uritemplate')
+pkgver=0.6
+pkgrel=0
+pkgdesc="a Python implementation of RFC6570"
+arch=('any')
+url="https://github.com/uri-templates/uritemplate-py/"
+license=('Apache')
+makedepends=('python2-setuptools' 'python-setuptools')
+source=("https://pypi.python.org/packages/source/u/uritemplate/uritemplate-${pkgver}.tar.gz")
+md5sums=('ecfc1ea8d62c7f2b47aad625afae6173')
+
+prepare() {
+ cd "$srcdir"
+ cp -a uritemplate-${pkgver} uritemplate-py2-${pkgver}
+ cd uritemplate-py2-${pkgver}
+
+ sed -e "s|#![ ]*/usr/bin/python$|#!/usr/bin/python2|" \
+ -e "s|#![ ]*/usr/bin/env python$|#!/usr/bin/env python2|" \
+ -e "s|#![ ]*/bin/env python$|#!/usr/bin/env python2|" \
+ -i $(find . -name '*.py')
+}
+
+build() {
+ msg "Building Python2"
+ cd "$srcdir"/uritemplate-py2-${pkgver}
+ python2 setup.py build
+
+ msg "Building Python3"
+ cd "$srcdir"/uritemplate-${pkgver}
+ python setup.py build
+}
+
+package_python2-uritemplate() {
+ depends=('python2')
+
+ cd "$srcdir"/uritemplate-py2-${pkgver}
+
+ python2 setup.py install --skip-build --root="$pkgdir" --optimize=1
+}
+
+package_python-uritemplate() {
+ depends=('python')
+
+ cd "$srcdir"/uritemplate-${pkgver}
+
+ python setup.py install --skip-build --root="$pkgdir" --optimize=1
+}
+
Property changes on: python-uritemplate/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list