[arch-commits] Commit in (4 files)
Sven-Hendrik Haase
svenstaro at archlinux.org
Sun Oct 26 22:01:07 UTC 2014
Date: Sunday, October 26, 2014 @ 23:01:07
Author: svenstaro
Revision: 121441
Prepare lib32-libpcap for wine
Added:
lib32-libpcap/
lib32-libpcap/repos/
lib32-libpcap/trunk/
lib32-libpcap/trunk/PKGBUILD
----------+
PKGBUILD | 44 ++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 44 insertions(+)
Added: lib32-libpcap/trunk/PKGBUILD
===================================================================
--- lib32-libpcap/trunk/PKGBUILD (rev 0)
+++ lib32-libpcap/trunk/PKGBUILD 2014-10-26 22:01:07 UTC (rev 121441)
@@ -0,0 +1,44 @@
+# Maintainer: Sven-Hendrik Haase <sh at lutzhaase.com>
+# Contributor: Christian Hesse <mail at eworm.de>
+# Contributor: Bill Fraser <wfraser at codewise.org>
+# Contributor: Thomas Bächler <thomas at archlinux.org>
+
+_pkgbasename=libpcap
+pkgname=lib32-libpcap
+pkgver=1.6.2
+pkgrel=1
+pkgdesc="A system-independent interface for user-level packet capture (32-bit)"
+arch=('x86_64')
+url="http://www.tcpdump.org/"
+license=('BSD')
+depends=('lib32-glibc' 'lib32-libnl' 'lib32-libusb' 'sh' "${_pkgbasename}")
+makedepends=('flex')
+source=("http://www.tcpdump.org/release/libpcap-${pkgver}.tar.gz"{,.sig})
+sha256sums=('5db3e2998f1eeba2c76da55da5d474248fe19c44f49e15cac8a796a2c7e19690'
+ 'SKIP')
+
+build() {
+ export CC="gcc -m32"
+ export CXX="g++ -m32"
+ export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+ cd ${srcdir}/${_pkgbasename}-${pkgver}
+ ./configure \
+ --prefix=/usr \
+ --libdir=/usr/lib32 \
+ --enable-ipv6 \
+ --enable-bluetooth=no
+ make
+}
+
+package() {
+ cd ${srcdir}/${_pkgbasename}-${pkgver}
+
+ make DESTDIR=${pkgdir} install
+
+ rm -rf ${pkgdir}/usr/lib32/libpcap.a
+ rm -rf ${pkgdir}/usr/{include,share,bin}
+
+ mkdir -p "${pkgdir}/usr/share/licenses"
+ ln -s ${_pkgbasename} "${pkgdir}/usr/share/licenses/${pkgname}"
+}
More information about the arch-commits
mailing list