[arch-commits] Commit in (5 files)

[Felix Yan]

    Date: Thursday, April 9, 2015 @ 08:32:47
  Author: fyan
Revision: 131012

addpkg: python-pyperclip 1.5.9-2

Added:
  python-pyperclip/
  python-pyperclip/repos/
  python-pyperclip/trunk/
  python-pyperclip/trunk/LICENSE.txt
  python-pyperclip/trunk/PKGBUILD

-------------+
 LICENSE.txt |   27 +++++++++++++++++++++++++++
 PKGBUILD    |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 77 insertions(+)

Added: python-pyperclip/trunk/LICENSE.txt
===================================================================
--- python-pyperclip/trunk/LICENSE.txt	                        (rev 0)
+++ python-pyperclip/trunk/LICENSE.txt	2015-04-09 06:32:47 UTC (rev 131012)
@@ -0,0 +1,27 @@
+Copyright (c) 2014, Al Sweigart
+All rights reserved.
+
+Redistribution and use in source and binary forms, with or without
+modification, are permitted provided that the following conditions are met:
+
+* Redistributions of source code must retain the above copyright notice, this
+  list of conditions and the following disclaimer.
+
+* Redistributions in binary form must reproduce the above copyright notice,
+  this list of conditions and the following disclaimer in the documentation
+  and/or other materials provided with the distribution.
+
+* Neither the name of the {organization} nor the names of its
+  contributors may be used to endorse or promote products derived from
+  this software without specific prior written permission.
+
+THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
+AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
+DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
+FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
+SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
+OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

Added: python-pyperclip/trunk/PKGBUILD
===================================================================
--- python-pyperclip/trunk/PKGBUILD	                        (rev 0)
+++ python-pyperclip/trunk/PKGBUILD	2015-04-09 06:32:47 UTC (rev 131012)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Jim Bridgewater <jwbwater at gmail dot com>
+# Contributor: delta48 <dark.magician.48[at]gmail[dot]com> 
+
+pkgbase=python-pyperclip
+pkgname=('python-pyperclip' 'python2-pyperclip')
+_pypiname=pyperclip
+pkgver=1.5.9
+pkgrel=2
+pkgdesc="A cross-platform clipboard module for Python"
+arch=('any')
+url="http://coffeeghost.net/2010/10/09/pyperclip-a-cross-platform-clipboard-module-for-python/"
+license=('BSD')
+makedepends=('python-setuptools' 'python2-setuptools' 'xclip')
+checkdepends=('xorg-server-xvfb')
+source=("https://pypi.python.org/packages/source/p/$_pypiname/$_pypiname-$pkgver.zip"
+        LICENSE.txt)
+md5sums=('aae99dd8d46e45197ac013350f691591'
+         'b6cd06fd72984ac1f8428337aec8cff7')
+
+prepare() {
+  cp -a $_pypiname-$pkgver{,-py2}
+}
+
+check() {
+  cd "$srcdir/$_pypiname-$pkgver"
+  xvfb-run python tests/basicTests.py
+
+  cd "$srcdir/$_pypiname-$pkgver-py2"
+  xvfb-run python2 tests/basicTests.py
+}
+
+package_python-pyperclip() {
+  depends=('python' 'xclip')
+
+  cd "$srcdir/$_pypiname-$pkgver"
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 ../LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+}
+
+package_python2-pyperclip() {
+  depends=('python2' 'xclip')
+
+  cd "$srcdir/$_pypiname-$pkgver-py2"
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 ../LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+}
+
+# vim:set ts=2 sw=2 et:


Property changes on: python-pyperclip/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property