[arch-commits] Commit in (5 files)
Andrzej Giniewicz
aginiewicz at archlinux.org
Fri Apr 17 07:16:15 UTC 2015
Date: Friday, April 17, 2015 @ 09:16:15
Author: aginiewicz
Revision: 131530
python-xlwt now supports python 3
Added:
python-xlwt/
python-xlwt/repos/
python-xlwt/trunk/
python-xlwt/trunk/PKGBUILD
Deleted:
python2-xlwt/
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Added: python-xlwt/trunk/PKGBUILD
===================================================================
--- python-xlwt/trunk/PKGBUILD (rev 0)
+++ python-xlwt/trunk/PKGBUILD 2015-04-17 07:16:15 UTC (rev 131530)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Andrzej Giniewicz <gginiu at gmail.com>
+# Contributor: Aaron DeVore <aaron.devore at gmail.com>
+# Contributor: David Moore <davidm at sjsoft.com>
+
+pkgbase=python-xlwt
+pkgname=('python2-xlwt' 'python-xlwt')
+pkgver=1.0.0
+pkgrel=0
+pkgdesc="Library to create spreadsheet files compatible with MS Excel 97/2000/XP/2003 XLS files"
+arch=('any')
+url="http://www.python-excel.org/"
+license=('BSD')
+makedepends=('python2-setuptools' 'python-setuptools')
+source=("https://pypi.python.org/packages/source/x/xlwt/xlwt-${pkgver}.tar.gz")
+md5sums=('5e5e4eae8fe7ee3d43f9324767ad925e')
+
+build() {
+ cd "$srcdir"
+ cp -a xlwt-${pkgver} xlwt-py2-${pkgver}
+
+ msg "Building Python2"
+ cd "$srcdir"/xlwt-py2-${pkgver}
+ python2 setup.py build
+
+ msg "Building Python3"
+ cd "$srcdir"/xlwt-${pkgver}
+ python setup.py build
+}
+
+package_python2-xlwt() {
+ depends=('python2')
+
+ cd "$srcdir"/xlwt-py2-${pkgver}
+
+ python2 setup.py install --skip-build --root="$pkgdir" --optimize=1
+
+ install -Dm644 docs/licenses.rst "$pkgdir/usr/share/licenses/$pkgname/licences.rst"
+}
+
+package_python-xlwt() {
+ depends=('python')
+
+ cd "$srcdir"/xlwt-${pkgver}
+
+ python setup.py install --skip-build --root="$pkgdir" --optimize=1
+
+ install -Dm644 docs/licenses.rst "$pkgdir/usr/share/licenses/$pkgname/licences.rst"
+}
+
Property changes on: python-xlwt/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list