[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Saturday, April 18, 2015 @ 09:19:42
  Author: fyan
Revision: 131608

addpkg: python-pathlib 1.0.1-2

Added:
  python-pathlib/
  python-pathlib/repos/
  python-pathlib/trunk/
  python-pathlib/trunk/PKGBUILD

----------+
 PKGBUILD |   35 +++++++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)

Added: python-pathlib/trunk/PKGBUILD
===================================================================
--- python-pathlib/trunk/PKGBUILD	                        (rev 0)
+++ python-pathlib/trunk/PKGBUILD	2015-04-18 07:19:42 UTC (rev 131608)
@@ -0,0 +1,35 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: vae77 <fernandogrd at yahoo.com.br> 
+
+pkgbase=python-pathlib
+pkgname=(python-pathlib python2-pathlib)
+pkgver=1.0.1
+pkgrel=2
+pkgdesc="This module offers a set of classes featuring all the common operations on paths in an easy, object-oriented way"
+arch=('any')
+url="http://pathlib.readthedocs.org/en/${pkgver}/"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools')
+source=("http://pypi.python.org/packages/source/p/pathlib/pathlib-${pkgver}.tar.gz")
+md5sums=('5099ed48be9b1ee29b31c82819240537')
+
+prepare() {
+  cp -a pathlib-$pkgver{,-py2}
+}
+
+package_python-pathlib() {
+  depends=('python')
+
+  cd "$srcdir/pathlib-$pkgver"
+  python setup.py install --root="$pkgdir/" --optimize=1
+  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+}
+
+package_python2-pathlib() {
+  depends=('python2')
+
+  cd "$srcdir/pathlib-$pkgver-py2"
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+}


Property changes on: python-pathlib/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property